Ru-Board.club
← Вернуться в раздел «В помощь системному администратору»

» vbs logon скрипт для подключения сетевых дисков

Автор: alfira
Дата сообщения: 16.12.2005 02:26
Подскажите пожалуйста как написать *.vbs logon скрипт который бы подключал несколько сетевых дисков несмотря на то что они раньше уже были назначены на другой путь

потому как если использовать команду:
Set objNetwork = Wscript.CreateObject("WScript.Network")
objNetwork.MapNetworkDrive "z:", "\\test\basa"
а этот диск к примеру уже существует и подключен к другому пути то выдается сообщение "имя локального устройства уже используется"

И еще вопрос существует ли способ подключать те или иные диски в зависимости от того в какой доменной групе находится пользователь? Под Novell Netware скриптом можно так сделать
Автор: finderknowledge
Дата сообщения: 16.12.2005 09:15
alfira
Сначала нужно проверить какие сетевые диски подключены:
objNetwork.EnumNetworkDrives()
потом отключить если на нужной букве что-то висит:
objNetwork.RemoveNetworkDrive("диск")


Цитата:
И еще вопрос существует ли способ подключать те или иные диски в зависимости от того в какой доменной групе находится пользователь?

можно с помощью обращений к ADSI:

var $strDomain = "SameDomen"
var $strUser = "SameUser";

function ingroup($strGroup) {    
var $objUser=GetObject ("WinNT://"+$strDomain+"/"+$strUser+",user");    
var $objGroup = GetObject("WinNT://"+$strDomain+"/"+$strGroup+",group");
if ($objGroup.IsMember($objUser.ADsPath))
    return true;
else
    return false;
}
Автор: SergeyCVS
Дата сообщения: 16.12.2005 11:20
вот два скрипта, первый проверяет принадлежнойть юзера к опред. группе, второй мапит сетевые диски с обработкой ошибок и занесением инфы в EventLog. на их основе написать скрипт мапящий диски на основе групп думаю не так сложно

Код: ON ERROR RESUME NEXT
Dim strUserDN, objSysInfo

set WshShell = CreateObject("WScript.Shell")
Set WshNetwork = WScript.CreateObject("WScript.Network")
Set objSysInfo = CreateObject("ADSystemInfo")

LogonServer=WshShell.ExpandEnvironmentStrings("%LogonServer%")
MsgBox "Logon server: " & LogonServer

strUserDN = objSysInfo.userName
MsgBox strUserDN

Set UserObj = GetObject("LDAP://" & strUserDN)

MsgBox "User '" & WshNetwork.username & "' connect to " & WshNetwork.computername

'Init Groups
Dim UserGroups
Dim GroupObj
UserGroups=""

For Each GroupObj In UserObj.Groups
UserGroups=UserGroups & "[" & GroupObj.Name & "]"
Next

MsgBox "Member of "& UserGroups

if InGroup("CN=Administrators") then
MsgBox "This user - Admin"
end if

Function InGroup(strGroup)
InGroup=False
If InStr(UserGroups,"[" & strGroup & "]") Then
InGroup=True
End If
End Function
Автор: alfira
Дата сообщения: 20.12.2005 05:30
дааа спасибо, но для меня к сожалению пока сложно самостоятельно написать скрипт мапящий диски на основе групп, потому как то, что вы для меня написали темный лес.
Чесно скажу, хотелось передрав код из справочной литературы быстро все сделать ан нет вижу не так-то все просто. Может подскажите с чего начать изучение vbs скриптов?
Автор: AlexSSS
Дата сообщения: 20.12.2005 10:22
если скрипты тебе нужны только для логонскриптов, могу посоветовать использовать KIX
http://forum.ru-board.com/topic.cgi?forum=8&topic=10659#1

это мощный коммандный процессор, ориентированный именно на логон скрипты
скажем, твоя задачка там решается примерно так

Use K: /DELETE /PERSISTENT
Use J: /DELETE /PERSISTENT

IF @UserID='_alex'
use k: '\\server\alex$'
ENDIF

IF INGROUP("Project9350")
Use J: "\\server\projects"
ENDIF
Автор: Jovanotti
Дата сообщения: 20.12.2005 18:10
alfira
В шапку Автоматизации загляни ....
Автор: hamet2000
Дата сообщения: 21.12.2005 04:56
SergeyCVS
Мне вот тоже хотелось бы иметь vbs скрипт мапящий диски на основе групп. и чтоб старые диски если таковые были подключены менялись на новые. Может уважаемый SergeyCVS извините за наглость выложит готовый скрипт мапящий несколько дисков на основе групп.
Автор: SergeyCVS
Дата сообщения: 21.12.2005 12:13
hamet2000
ну что-то вроде этого

Код: '==========================================================================
'
' VBScript Source File
'
' NAME: MapDrivesInGroup.vbs
'
' AUTHOR: SergeyCVS
'
' COMMENT: Подключение сетевых дисков на основе групп с записью ошибок в EventLog
'
'==========================================================================

Option Explicit
'On Error Resume Next

Dim WshShell, WshNetwork
Dim strUserDN, objSysInfo, GroupObj, UserGroups, UserObj

UserGroups=""


Set WshShell = WScript.CreateObject("WScript.Shell")
Set objSysInfo = CreateObject("ADSystemInfo")

strUserDN = objSysInfo.userName

Set UserObj = GetObject("LDAP://" & strUserDN)

For Each GroupObj In UserObj.Groups
UserGroups=UserGroups & "[" & GroupObj.Name & "]"
Next

'MsgBox "Member of "& UserGroups

if InGroup("Supports Admins") then
MapDrv "Z:", "\\SRV\SUPPORT$"
end if

if InGroup("1C Users") then
MapDrv "W:", "\\SRV\Base"
end if


MapDrv "L:", "\\SRV\Users\" & WshShell.ExpandEnvironmentStrings("%USERNAME%")


'==========================================================================
'
' Function MapDrv(DrvLet, UNCPath)
'
' DrvLet - Буква устройства
' UNCPath - Сетевой путь
'
' COMMENT: Подключение сетевых дисков с записью ошибок в EventLog
'
'==========================================================================


Function MapDrv(DrvLet, UNCPath)

Dim WshNetwork ' Object variable
Dim Msg

Set WshNetwork = WScript.CreateObject("WScript.Network")

On Error Resume Next
WshNetwork.RemoveNetworkDrive DrvLet
WshNetwork.MapNetworkDrive DrvLet, UNCPath

Select Case Err.Number
Case 0 ' No error

Case -2147023694
WshNetwork.RemoveNetworkDrive DrvLet
WshNetwork.MapNetworkDrive DrvLet, UNCPath

Case -2147024811
WshNetwork.RemoveNetworkDrive DrvLet
WshNetwork.MapNetworkDrive DrvLet, UNCPath

Case Else

Msg = "Mapping network drive error: " & _
CStr(Err.Number) & " 0x" & Hex(Err.Number) & vbCrLf & _
"Error description: " & Err.Description & vbCrLf
Msg = Msg & "Domain: " & WshNetwork.UserDomain & vbCrLf
Msg = Msg & "Computer Name: " & WshNetwork.ComputerName & vbCrLf
Msg = Msg & "User Name: " & WshNetwork.UserName & vbCrLf & vbCrLf
Msg = Msg & "Device name: " & DrvLet & vbCrLf
Msg = Msg & "Map path: " & UNCPath

WshShell.LogEvent 1, Msg, "\\SRV"
End Select
End Function


'==========================================================================
'
' Function InGroup(strGroup)
'
' strGroup - группа, принадлежность к которой проверяем
'
' COMMENT: проверка принадлежности пользователя к группе
'
'==========================================================================

Function InGroup(strGroup)
InGroup=False
If InStr(UserGroups,"[CN=" & strGroup & "]") Then
InGroup=True
End If
End Function
Автор: hamet2000
Дата сообщения: 23.12.2005 05:00
SergeyCVS
Спасибо огромное! Диски подключаются, только есть проблемы.
Если пользователь вручную назначил диск то скрипт такой диск не переназначает на тот путь который я назначил в скрипте, а оставляет его таким каким его сделал пользователь.
и вот еще о тех дисках которые успешно подключились почему-то в логах пишутся сообщения например:

Тип события:    Ошибка
Источник события:    WSH
Категория события:    Отсутствует
Код события:    1
Дата:        23.12.2005
Время:        11:37:45
Пользователь:        Н/Д
Компьютер:    Hamet
Описание:
Mapping network drive error: -2147022646 0x800708CA
Error description: Сетевое подключение не существует.

Domain: STAA
Computer Name: hamet
User Name: admin

Device name: H:
Map path: \\server\basa

Дополнительные сведения можно найти в центре справки и поддержки, в "http://go.microsoft.com/fwlink/events.asp".
Хотя диски и этот в часности подключен.
Автор: SergeyCVS
Дата сообщения: 23.12.2005 10:22
hamet2000
какая версия wsh у тя?
Автор: hamet2000
Дата сообщения: 26.12.2005 01:12
SergeyCVS
а где это посмотреть?
Автор: SergeyCVS
Дата сообщения: 26.12.2005 10:21
hamet2000
cscript /?
Автор: hamet2000
Дата сообщения: 26.12.2005 11:17
SergeyCVS
Версия 5.6
Автор: SergeyCVS
Дата сообщения: 26.12.2005 18:24
hamet2000

Цитата:
и вот еще о тех дисках которые успешно подключились почему-то в логах пишутся сообщения например:

Тип события: Ошибка
Источник события: WSH
Категория события: Отсутствует
Код события: 1
Дата: 23.12.2005
Время: 11:37:45
Пользователь: Н/Д
Компьютер: Hamet
Описание:
Mapping network drive error: -2147022646 0x800708CA
Error description: Сетевое подключение не существует.

fixed

[more=MapDrivesInGroup.vbs]
Код:
'==========================================================================
'
' VBScript Source File
'
' NAME: MapDrivesInGroup.vbs
'
' AUTHOR: SergeyCVS
'
' COMMENT: Подключение сетевых дисков на основе групп с записью ошибок в EventLog
'
'==========================================================================

Option Explicit
'On Error Resume Next

Dim WshShell, WshNetwork
Dim strUserDN, objSysInfo, GroupObj, UserGroups, UserObj

UserGroups=""


Set WshShell = WScript.CreateObject("WScript.Shell")
Set objSysInfo = CreateObject("ADSystemInfo")

strUserDN = objSysInfo.userName

Set UserObj = GetObject("LDAP://" & strUserDN)

For Each GroupObj In UserObj.Groups
UserGroups=UserGroups & "[" & GroupObj.Name & "]"
Next

'MsgBox "Member of "& UserGroups

if InGroup("Domain Admins") then
MapDrv "Z:", "\\SRV\SUPPORT$"
end if

if InGroup("1C Users") then
MapDrv "W:", "\\SRV\Base"
end if


MapDrv "L:", "\\SRV\Users\" & WshShell.ExpandEnvironmentStrings("%USERNAME%")


'==========================================================================
'
' Function MapDrv(DrvLet, UNCPath)
'
' DrvLet - Буква устройства
' UNCPath - Сетевой путь
'
' COMMENT: Подключение сетевых дисков с записью ошибок в EventLog
'
'==========================================================================


Function MapDrv(DrvLet, UNCPath)

Dim WshNetwork,objFSO ' Object variable
Dim Msg

Set WshNetwork = WScript.CreateObject("WScript.Network")
Set objFSO = CreateObject("Scripting.FileSystemObject")

On Error Resume Next

If objFSO.DriveExists(DrvLet) Then
WshNetwork.RemoveNetworkDrive DrvLet
End If

WshNetwork.MapNetworkDrive DrvLet, UNCPath

Select Case Err.Number
Case 0 ' No error

Case -2147023694
WshNetwork.RemoveNetworkDrive DrvLet
WshNetwork.MapNetworkDrive DrvLet, UNCPath

Case -2147024811
WshNetwork.RemoveNetworkDrive DrvLet
WshNetwork.MapNetworkDrive DrvLet, UNCPath

Case Else

Msg = "Mapping network drive error: " & _
CStr(Err.Number) & " 0x" & Hex(Err.Number) & vbCrLf & _
"Error description: " & Err.Description & vbCrLf
Msg = Msg & "Domain: " & WshNetwork.UserDomain & vbCrLf
Msg = Msg & "Computer Name: " & WshNetwork.ComputerName & vbCrLf
Msg = Msg & "User Name: " & WshNetwork.UserName & vbCrLf & vbCrLf
Msg = Msg & "Device name: " & DrvLet & vbCrLf
Msg = Msg & "Map path: " & UNCPath

WshShell.LogEvent 1, Msg, "\\SRV"
End Select
End Function


'==========================================================================
'
' Function InGroup(strGroup)
'
' strGroup - группа, принадлежность к которой проверяем
'
' COMMENT: проверка принадлежности пользователя к группе
'
'==========================================================================

Function InGroup(strGroup)
InGroup=False
If InStr(UserGroups,"[CN=" & strGroup & "]") Then
InGroup=True
End If
End Function
Автор: alfira
Дата сообщения: 27.12.2005 15:59
ух ты да тут вовсю уже эту тему продолжают.
скрипт класный!
последний fixed скрипт почему-то не отключает старые сетевые диски которые пользователи сами подключали с галкой "восстанавливать сетевые подключения".

помоему hamet тоже про это? писал?
SergeyCVS
спасибо !!!
Автор: SergeyCVS
Дата сообщения: 27.12.2005 16:13
alfira

Цитата:
последний fixed скрипт почему-то не отключает старые сетевые диски которые пользователи сами подключали с галкой "восстанавливать сетевые подключения".

скрипт откл. только те диски, литеры которых планеруется использовать. все сетевые диски скрипт не откл.
Автор: hamet2000
Дата сообщения: 28.12.2005 05:21
SergeyCVS
скрипт не во всех случаях отключает "те диски, литеры которых планируется использовать".
проверял так:
прописываю в скрипте mapdisk.vbs что диск Z: нужно подключить группе managers сетевой путь \\server\basa
далее, допустим пользователь член группы managers самостоятельно когда-то подключил диск Z: допустим к \\OldServer\oldbasa с галкой "восстанавливать сетевые подключения", запускаю mapdisk.vbs на компе этого пользователя и вижу что скрипт к сожалению такой диск не может отключить и подключить на верный путь который в скрипте прописан.
пробовал уже по всякому. а вот если подключить диск Z: вручную но без галки "восстанавливать сетевые подключения". и запустить mapdisk.vbs то все нормально проходит, диск подключается согласно прописанному в скрипте пути.
Автор: SergeyCVS
Дата сообщения: 28.12.2005 10:35
hamet2000
сегодня попробую похожую ситуацию

Добавлено:

[more=пробуем]
Код: '==========================================================================
'
' VBScript Source File
'
' NAME: MapDrivesInGroup.vbs
'
' AUTHOR: SergeyCVS
'
' COMMENT: Подключение сетевых дисков на основе групп с записью ошибок в EventLog
'
'==========================================================================

Option Explicit
'On Error Resume Next

Dim WshShell, WshNetwork
Dim strUserDN, objSysInfo, GroupObj, UserGroups, UserObj

UserGroups=""


Set WshShell = WScript.CreateObject("WScript.Shell")
Set objSysInfo = CreateObject("ADSystemInfo")

strUserDN = objSysInfo.userName

Set UserObj = GetObject("LDAP://" & strUserDN)

For Each GroupObj In UserObj.Groups
UserGroups=UserGroups & "[" & GroupObj.Name & "]"
Next

'MsgBox "Member of "& UserGroups

if InGroup("Domain Admins") then
MapDrv "Z:", "\\SRV\SUPPORT$"
end if

if InGroup("1C Users") then
MapDrv "W:", "\\SRV\Base"
end if


MapDrv "L:", "\\SRV\Users\" & WshShell.ExpandEnvironmentStrings("%USERNAME%")


'==========================================================================
'
' Function MapDrv(DrvLet, UNCPath)
'
' DrvLet - Буква устройства
' UNCPath - Сетевой путь
'
' COMMENT: Подключение сетевых дисков с записью ошибок в EventLog
'
'==========================================================================


Function MapDrv(DrvLet, UNCPath)

Dim WshNetwork,objFSO ' Object variable
Dim Msg

Set WshNetwork = WScript.CreateObject("WScript.Network")
Set objFSO = CreateObject("Scripting.FileSystemObject")

On Error Resume Next

If objFSO.DriveExists(DrvLet) Then
WshNetwork.RemoveNetworkDrive DrvLet, true, true
End If

WshNetwork.MapNetworkDrive DrvLet, UNCPath

Select Case Err.Number
Case 0 ' No error

Case -2147023694
WshNetwork.RemoveNetworkDrive DrvLet, true, true
WshNetwork.MapNetworkDrive DrvLet, UNCPath

Case -2147024811
WshNetwork.RemoveNetworkDrive DrvLet, true, true
WshNetwork.MapNetworkDrive DrvLet, UNCPath

Case Else

Msg = "Mapping network drive error: " & _
CStr(Err.Number) & " 0x" & Hex(Err.Number) & vbCrLf & _
"Error description: " & Err.Description & vbCrLf
Msg = Msg & "Domain: " & WshNetwork.UserDomain & vbCrLf
Msg = Msg & "Computer Name: " & WshNetwork.ComputerName & vbCrLf
Msg = Msg & "User Name: " & WshNetwork.UserName & vbCrLf & vbCrLf
Msg = Msg & "Device name: " & DrvLet & vbCrLf
Msg = Msg & "Map path: " & UNCPath

WshShell.LogEvent 1, Msg, "\\SRV"
End Select
End Function


'==========================================================================
'
' Function InGroup(strGroup)
'
' strGroup - группа, принадлежность к которой проверяем
'
' COMMENT: проверка принадлежности пользователя к группе
'
'==========================================================================

Function InGroup(strGroup)
InGroup=False
If InStr(UserGroups,"[CN=" & strGroup & "]") Then
InGroup=True
End If
End Function
Автор: hamet2000
Дата сообщения: 29.12.2005 04:57
Все отлично работает!!!
Автор: sVx
Дата сообщения: 25.01.2006 09:52
переименовать диск:

Код: mDrive = "W:\"
Set oShell = CreateObject("Shell.Application")
oShell.NameSpace(mDrive).Self.Name = "Base"

mDrive = "L:\"
Set oShell = CreateObject("Shell.Application")
oShell.NameSpace(mDrive).Self.Name = WshNetwork.UserName & "'s disk"
Автор: SergeyCVS
Дата сообщения: 25.01.2006 10:20
sVx
ок, гляну

Добавлено:
sVx

[more=смотрим, MapDrivesInGroup.vbs, v1.1 добавил возможность именование сетевых дисков в проводнике]
Код:
'==========================================================================
'
' VBScript Source File
'
' NAME: MapDrivesInGroup.vbs
'
' VERSION: v1.1
'
' AUTHOR: SergeyCVS
'
' COMMENT: Подключение сетевых дисков на основе групп с записью ошибок в EventLog
'
'==========================================================================

Option Explicit
'On Error Resume Next

Dim WshShell, WshNetwork
Dim strUserDN, objSysInfo, GroupObj, UserGroups, UserObj

' Задаем имя файлового сервера, при использовании нескольких серверов
' создаем несколько констант и используем их при вызове MapDrv
Const FileSrv1 = "\\SRV1"
'Const FileSrv2 = "\\SRV2"

UserGroups=""


Set WshShell = WScript.CreateObject("WScript.Shell")
Set WshNetwork = WScript.CreateObject("WScript.Network")
Set objSysInfo = CreateObject("ADSystemInfo")

strUserDN = objSysInfo.userName

Set UserObj = GetObject("LDAP://" & strUserDN)

For Each GroupObj In UserObj.Groups
UserGroups=UserGroups & "[" & GroupObj.Name & "]"
Next

'MsgBox "Member of "& UserGroups

if InGroup("Domain Admins") then
MapDrv "P:", FileSrv1 & "\SUPPORT$","Tools & Apps"
end if

if InGroup("1C Users") then
MapDrv "W:", FileSrv1 & "\Base","Базы 1С"
end if

MapDrv "L:", FileSrv1 & "\Users\" & WshNetwork.UserName, WshNetwork.UserName & "'s personal disk"
MapDrv "R:", FileSrv1 & "\Archive", "Архив"
MapDrv "U:", FileSrv1 & "\Users","All Users"
MapDrv "W:", FileSrv1 & "\Work","Проекты"


'==========================================================================
'
' Function MapDrv(DrvLet, UNCPath, DrvName)
'
' DrvLet - Буква устройства
' UNCPath - Сетевой путь
' DrvName - Название диска отображаемое в проводнике Windows
'
' COMMENT: Подключение сетевых дисков с записью ошибок в EventLog
'
'==========================================================================


Function MapDrv(DrvLet, UNCPath, DrvName)

Dim objFSO, oShell ' Object variable
Dim Msg

Set objFSO = CreateObject("Scripting.FileSystemObject")
Set oShell = CreateObject("Shell.Application")

On Error Resume Next

If objFSO.DriveExists(DrvLet) Then
WshNetwork.RemoveNetworkDrive DrvLet, true, true
End If

WshNetwork.MapNetworkDrive DrvLet, UNCPath
oShell.NameSpace(DrvLet).Self.Name = DrvName

Select Case Err.Number
Case 0 ' No error

Case -2147023694
WshNetwork.RemoveNetworkDrive DrvLet, true, true
WshNetwork.MapNetworkDrive DrvLet, UNCPath
oShell.NameSpace(DrvLet).Self.Name = DrvName

Case -2147024811
WshNetwork.RemoveNetworkDrive DrvLet, true, true
WshNetwork.MapNetworkDrive DrvLet, UNCPath
oShell.NameSpace(DrvLet).Self.Name = DrvName

Case Else

Msg = "Mapping network drive error: " & _
CStr(Err.Number) & " 0x" & Hex(Err.Number) & vbCrLf & _
"Error description: " & Err.Description & vbCrLf
Msg = Msg & "Domain: " & WshNetwork.UserDomain & vbCrLf
Msg = Msg & "Computer Name: " & WshNetwork.ComputerName & vbCrLf
Msg = Msg & "User Name: " & WshNetwork.UserName & vbCrLf & vbCrLf
Msg = Msg & "Device name: " & DrvLet & vbCrLf
Msg = Msg & "Map path: " & UNCPath

WshShell.LogEvent 1, Msg, FileSrv1
End Select
End Function


'==========================================================================
'
' Function InGroup(strGroup)
'
' strGroup - группа, принадлежность к которой проверяем
'
' COMMENT: проверка принадлежности пользователя к группе
'
'==========================================================================

Function InGroup(strGroup)
InGroup=False
If InStr(UserGroups,"[CN=" & strGroup & "]") Then
InGroup=True
End If
End Function
Автор: sVx
Дата сообщения: 27.01.2006 09:24
Спасибо.
Работает (но только под Windows XP и Windows 2003,
на Windows 2000 не периеменовывает сетевой диск в проводнике)
Автор: SergeyCVS
Дата сообщения: 27.01.2006 12:58
sVx

Цитата:
на Windows 2000 не периеменовывает сетевой диск в проводнике

я неуверен что эта фича вааще под Win2k должна работать
Автор: sVx
Дата сообщения: 28.01.2006 18:00
так работает.

Код: mDrive = "W:\"
Set oShell = CreateObject("Shell.Application")
oShell.NameSpace(mDrive).Self.Name = "Base"
Автор: SergeyCVS
Дата сообщения: 28.01.2006 22:20
sVx
у меня, к сожелению, вин2к нет под рукой, проверить не начем. у тя на вин2к версия wsh какая (cscript /?)?
Автор: sVx
Дата сообщения: 30.01.2006 06:04
Название ОС    Microsoft Windows 2000 Professional
Версия     5.0.2195 Service Pack 4 сборка 2195

Сервер сценариев Windows (Microsoft R) версия 5.6
Автор: SergeyCVS
Дата сообщения: 30.01.2006 09:53
sVx
попробуй такой вар-т у себя на вин2к, он без "\" в первой строке. имхо, эт без разницы, но других идей пока у меня нет

Код: mDrive = "W:"
Set oShell = CreateObject("Shell.Application")
oShell.NameSpace(mDrive).Self.Name = "Base"
Автор: sVx
Дата сообщения: 30.01.2006 11:36
без "\" в вин2к тоже не работает.
буду запускать mDrive = "W:\" отдельным скриптом на вин2к.
Спасибо за помощь.
Автор: SergeyCVS
Дата сообщения: 31.01.2006 10:23
sVx
так ты попробуй мой скрипт исправить, вызывая фун. MapDrv указывай литеру диска с "\" т.е.

Код: MapDrv "W:\", FileSrv1 & "\Work","Проекты"
Автор: sVx
Дата сообщения: 02.02.2006 14:26
SergeyCVS

Код: MapDrv "W:\", FileSrv1 & "\Work","Проекты"

Страницы: 1234

Предыдущая тема: Настройка Kiwi Syslog Daemon под DFL700


Форум Ru-Board.club — поднят 15-09-2016 числа. Цель - сохранить наследие старого Ru-Board, истории становления российского интернета. Сделано для людей.