» Задачи на bat-файлах 7

Цитата:

есть файлы с именем EJxxxx, необходимо изменить имена на ELxxxx, и к измененному имени добавить текущую дату.

для файлов с именами без расширения - это делается в одну команду,
ren EJ* EL*%date%

с расширением - правишь первый вариснт 01MDM


Код: @echo off
setlocal
for /f "tokens=*" %%i in ('dir /b EJ*') do call:rename "%%i"
goto:eof

:rename
set "name=%~n1"
set name
ren %1 "%name:EJ=EL%%date%%~x1"

смотрите что нашел
"%userprofile%\0016~1" - это папка "Рабочий стол"

Цитата:

"%userprofile%\0016~1" - это папка "Рабочий стол"

У тебя на компе - возможно, хотя и странновато

Господа, разбирающиеся, помогите... есть задача: пинговать оределенные адреса маршрутизаторов D-link 804HV (192.168.1.x, 192.168.2.x и т.д.) в случае не отклика запустить ребут... по средствам http://192.168.1.x/x.htm

реальна ли реализация этого с помощью батника, если да прошу: направить на путь истинный и показать как это выглядит.

заранее благодарен, с уважением...

wolf0425
У тебя не катит?
Я когда себе турбо С ставил увидел что он у меня так отображает рабочий стол

Добавлено:
spilanto

Цитата:

192.168.1.x, 192.168.2.x и т.д.

x-значит произвольное число? т.е. нужно все такие адруса пропинговать 192.168.Х.Х ?
запустить ребут чего? + по каким средствам? что надо ссделать с http://192.168.1.x/x.htm ?

есть маршрутизатор D-link c ip - 192.168.1.1 он переодически теряет VPN тонель, помогает только ребут через его веб интерфейс. в адресной строке браузера это выглядит следующим образом http://admin:1234@192.168.1.1/x.htm

в айпи - х - произвольное число.

верное пропинговать нужно 192.168.х.х

запустить ребут маршрутизатора по средствам браузера в адресной строке которого должно быть - http://admin:1234@192.168.1.1/x.htm

Помогите советом, мне необходимо, чтобы bat файл закрывал нужное приложение, если оно запущено. В итоге написал код:
Taskkill /F /IM Program.exe

А как теперь прописать, чтобы bat ничего не делал, если такого приложение в task manager нету, другими словами просто закрывался.

Цитата:

А как теперь прописать, чтобы bat ничего не делал, если такого приложение в task manager нету, другими словами просто закрывался.

вообще-то если Program.exe не запущен - твой вариант и так ничего кроме сообщения об отсутствии Program.exe не делает.
но если хочешь проверить заранее, или проверить одну программу а закрыть другую - то че-то типа такого:

Код: tasklist | find /i "Program.exe" && echo Program.exe is working

Цитата:

Помогите советом, мне необходимо, чтобы bat файл закрывал нужное приложение, если оно запущено. В итоге написал код:
Taskkill /F /IM Program.exe

Код: tasklist | find /i "Program.exe" && Taskkill /F /IM "Program.exe"

wolf0425
Robby
спасибо

HaK1R

Цитата:

смотрите что нашел
"%userprofile%\0016~1" - это папка "Рабочий стол"

Вполне нормальное отображение в command.com. Раскладка переключается?

01MDM
неа

HaK1R

Код:
echo NTCMDPROMPT 1>>%systemroot%\system32\config.nt
shutdown /r /t 0

Есть проблема - нужен батник на перезагрузку компьютера, при зависании службы или ошибке службы, или незапущенной службе..............

Заранее огромной спасибо!!!!!!!!!!!!!!

Добрый день! Прошу помощи.

Как сделать жизнеспособным такой батник (написал скорее в логическом виде нежели практическом):


Код: @echo off

rem Задаем время, когда компьютер должен выключиться
set NeedTime=18:00

rem Получаем текущее системное время
set CurTime=%TIME%

rem Вычисляем сколько от текущего момента осталось секунд до заданного момента
set /a RESULT=NeedTime - CurTime

rem Выключаем компьютер после отсчета заданного интервала
shutdown -s -f -t %RESULT%

exit

Shadow4
Ну перезагрузить shutdown -r Если нужно завершать с коментом то добавь параметр -с "комментарий" а вот остальное.
Вот нашел кое что, вроде даже посты уважаемого 01MDM.

Код:
@echo off

for /f "tokens=4" %%i in ('sc query ServiceName ^| findstr /i "state"') do (
set checksrv=%%i
)
if %checksrv%=="running" (
:: Код если служба запущена:
echo ServiceName %checksrv%
) else (
:: Код если служба остановлена:
echo ServiceName %checksrv%
)

anachrom
Да, это мой батник, правда уже прошло..

Цитата:

Но почему то в условии выбирается else.

Просто к условию if %checkserv% надо добавить ключ /i или писать "RUNNING" На примере сервиса "Themes":

Код:
@echo off
setlocal

for /f "tokens=4" %%i in ('sc query themes ^| findstr /i "state"') do (
set "checksrv=%%i"
)

if /i "%checksrv%"=="running" (
:: Код если служба запущена:
echo themes %checksrv%
) else (
:: Код если служба остановлена:
echo themes %checksrv%
)

01MDM

Цитата:

Может лучше через планировщик?
...
И не будет висеть countdown.

Соль в том - чтобы как раз созерцать countdown
Необходим именно ручной запуск.

fargo44
Получай:

Код:
@echo off
setlocal

for /f "tokens=1-3 delims=:" %%i in ("18:00:00") do set /a time_ch=((1%%i-100)*3600)+((1%%j-100)*60)+1%%k-100
for /f "tokens=1-3 delims=:" %%i in ("%time:~0,-3%") do set /a cur_time=((1%%i-100)*3600)+((1%%j-100)*60)+1%%k-100

set /a wait=time_ch-cur_time

shutdown /s /f /t %wait%

Огромное спасибо - именно то, что нужно!

fargo44
Я немного исправил, на случай 08 и 09, которые воспринимаются как восмеричные.

Shadow4
И того имеем:

Код:
@echo off
setlocal

for /f "tokens=4" %%i in ('sc query themes ^| findstr /i "state"') do (
set "checksrv=%%i"
)

if /i "%checksrv%"!==!"running" (
shutdown -r
)

Подскажите, пожалуйста, как можно средствами bat организовать следующую штуку?

Команда netsh interface ip show config дает вывод в виде:


Код: Настройка интерфейса "Канал к коллективному разуму"
DHCP разрешен: Нет
IP-адрес: 192.168.4.6
Маска подсети: 255.255.255.0
Основной шлюз: 192.168.4.1
Метрика шлюза: 0
Метрика интерфейса: 0
Статически настроенные DNS-серверы: 192.168.6.254
Статически настроенные WINS-серверы: Отсутствует
Зарегистрировать с суффиксом: Только основной

anachrom

@echo off
setlocal

for /f "tokens=4" %%i in ('sc query themes ^| findstr /i "state"') do (
set "checksrv=%%i"
)

if /i "%checksrv%"!==!"running" (
shutdown -r
)

так вышепрописанное тупо скопировать и в планировщик?????
как я понял sc query themes - название службы????

искал и не нашел в сети такой информации. может вы поможете?
вот сделал скрипт такой
for %%i in (.\input\*.*) do "%~dp0converter\ffmpeg.exe" -i "%%~fi" -vn -acodec pcm_s16le -ar 44100 -ac 2 ".\temp\%%~ni.wav"
for %%i in (.\temp\*.wav) do "%~dp0converter\neroAacEnc.exe" -ignorelength -lc -cbr 96000 -if "%%~fi" -of ".\output\%%~ni.m4a"

поясню. сначала из пакпи INPUT обрабатывается пачка файлов через ffmpeg в папку temp. потом файлы из темпа обрабатываются через neroAacEnc и идут в папку output (допустим таких файлов 100). на деле выходит так. сначала обрабатывается вся сотня через ффмпег потом вся сотня через нероаас.. как бы сделать чтобы файлы обрабатывались поединично? сначала файл 1 обрабатывается обоими программами..потом файл 2...и так далее..?

Shadow4
Название службы это themes (позволяет упровлять оформлением рабочей области). sc query это сборка команд позволяющая вывести статус сервиса.
При копировании с форума, не забудте удалить в конце каждой строки пробелы, в шапке про это написано в самом начале.

Добавлено:
fd1136
"Канал к коллективному разуму" - это сильно.

fd1136

Цитата:

Хотелось-бы записать в файл только

Код:
@echo off
setlocal

for /f "tokens=*" %%i in ('netsh interface ip show config') do call:parse "%%i"
goto:eof

:parse
set "str="
echo %~1 | 1>nul findstr \".*\" && (
for /f "tokens=3*" %%i in (%1) do echo %%i %%j 1>>file.txt
goto:eof
)

for /f "tokens=2 delims=:" %%i in ('echo %~1 ^| findstr [0-9]') do set "str=%%i"
if not "%str%"=="" echo %str:~1% 1>>file.txt

Как указать что имя файла, в который будет все записываться будет носить имя компьютера. Команда hostname позволяет выводить это имя, но вот с файлом ... имя файла так и остается hostname.

526549


Код: for %%i in (.\input\*.*) do (
"%~dp0converter\ffmpeg.exe" -i "%%~fi" -vn -acodec pcm_s16le -ar 44100 -ac 2 ".\temp\%%~ni.wav"
"%~dp0converter\neroAacEnc.exe" -ignorelength -lc -cbr 96000 -if ".\temp\%%~ni.wav" -of ".\output\%%~ni.m4a"
)

king_stiven
спасибо большое, помогло.
P.s. никому не надо консольный конвертер видео в 264 в два прохода?