» Командная строка, батники, сценарии (bat, cmd) 2

lid111
Сразу оговорюсь - не тестировал

Код:
@echo off
setlocal
echo Start....
for %%i in (Q W E R T Y U I P O A S D F G H J K L Z X C V B N M) do (
if not %~d0==%%i: call:clean %%i
)
echo ....Done
goto:eof

:clean
if exist %1:\Windows\Temp (del /s /a /q %1:\Windows\Temp\* 1>nul 2>&1)
if exist %1:\WinNT\Temp (del /s /a /q %1:\WinNT\Temp\* 1>nul 2>&1)
if exist "%1:\Documents and Settings" (
for /d %%i in ("%1\Documents and Settings\*") do (
del /s /a /q "%%i\Local Settings\Temp\*" 1>nul 2>&1
del /s /a /q "%%i\Local Settings\Temporary Internet Files\*" 1>nul 2>&1
)
)

Спасибо огромное за труды откликнувшимся, скоро попробую.
Пока вопрос: Если батник находится, например, на USB-харде, там же, где антивирусное ПО, которое после него запускается, а система загружается с CD, то файл, предложенный в предыдущем посте 01MDM, должен пропустить USB-носитель.
А эти каталоги, которые мы сносим, существуют на загрузочном диске? Наверно, вряд ли - поскольку запись в эти временные папки совершенно невозможна. Но при загрузке ОС создается еще виртуальный диск с какой-то своей буквой. Нет ли на нем папок с такими именами? Не может ли быть в них чего-то важного? Я не знаю. Можно, конечно, загрузиться и посмотреть. Но сегодня это может быть диск WinPE, в другой раз - ERD Commander, в третий - еще что-то, а я не в курсе, одинаковые ли там механизмы... Как бы всё предусмотреть.

lid111
Если батник находится на usb, то его он должен пропустить. С самого cd он ничего удалить не сможет физически, а с RAM диска наверное сможет, если тот создает временные папки, которые соответствуют пути в батнике. В любом случае лучше проверить. Измени в скрипте пути на какую-нибудь Test-папку.

01MDM, сейчас проверил ваш файл, запустив его с дискеты после загрузки на виртуальной машине WinPE. Только в директориях Windows\Temp и WinNT\Temp (вторую создал специально) удалились все файлы (правда, остались на месте все подкаталоги). ВСЕГО ОСТАЛЬНОГО ИЗМЕНЕНИЯ НЕ КОСНУЛИСЬ.

lid111

Я же говорю, что не тестировал.. Измени черную часть:

Код:

@echo off
setlocal
echo Start....
for %%i in (Q W E R T Y U I P O A S D F G H J K L Z X C V B N M) do (
if not %~d0==%%i: call:clean %%i
)
echo ....Done
goto:eof

:clean
if exist %1:\Windows\Temp (del /s /a /q %1:\Windows\Temp\* 1>nul 2>&1)
if exist %1:\WinNT\Temp (del /s /a /q %1:\WinNT\Temp\* 1>nul 2>&1)

if not exist "%1:\Documents and Settings" goto:eof
for /d %%i in ("%1:\Documents and Settings\*") do (
del /s /a /q "%%i\Local Settings\Temp\*" 1>nul 2>&1
del /s /a /q "%%i\Local Settings\Temporary Internet Files\*" 1>nul 2>&1
)

01MDM, дальнейшие результаты тестирования: исправленный как вами указано батник полностью не затрагивает содержимое трех папок в Documents and Settings: \Default User, \LocalService и \NetworkService.
Кроме того, в любой папке не удаляются файлы с атрибутом только для чтения, то есть надо добавить сброс атрибутов. Я сам наполнял папки для тестирования, может, временных файлов и не бывает только для чтения, не знаю, но, думаю, на всякий случай, стоит добавить сброс атрибутов.

Ребята опять к вам за помощью.

Нужно чтобы батник мог по прямой ссылки Пример: http://forum.ru-board.com/ups.exe скачать файл в ту же директорию и запустить его.

lid111


Код:
@echo off
setlocal

set "ds=Documents and Settings"
set "tf=Local Settings\Temp"
set "ti=Local Settings\Temporary Internet Files"

echo Start....

for %%i in (Q W E R T Y U I P O A S D F G H J K L Z X C V B N M) do (
if not %~d0==%%i: call:clean %%i
)

echo ....Done
goto:eof

:clean

if exist %1:\Windows\Temp (
pushd %1:\Windows\Temp
call:delete
popd
)

if exist %1:\WinNT\Temp (
pushd %1:\WinNT\Temp
call:delete
popd
)

if not exist "%1:\%ds%" goto:eof
for /f "tokens=*" %%i in ('dir /b /ad "%1:\%ds%"') do (
if exist "%1:\%ds%\%%i\%tf%" (
pushd "%1:\%ds%\%%i\%tf%"
call:delete
popd
)
if exist "%1:\%ds%\%%i\%ti%" (
pushd "%1:\%ds%\%%i\%ti%"
call:delete
popd
)
)
goto:eof

:delete
del /q /a /f *.* 1>nul 2>&1
for /f "tokens=*" %%i in ('dir /b /ad') do rd /s /q "%%i" 1>nul 2>&1

01MDM Спасибо!

01MDM, когда я выделяю содержимое файла в рамке, внизу - пустая строка - она нужна или убирать?

lid111
Это не важно, пустые строки не обрабатываются, а вот лишние пробелы..

01MDM, браво - наконец-то стопроцентное попадание!!! Остался неубитым только файл index.dat в Default User\local Settings\Temporary Internet Files на виртуальном диске, а в остальном сносится всё, даже index.dat везде! Вы говорили, что можно добавить очистку корзины - как это сделать? И заодно - можно ли добавить удаление точек восстановления (кроме последней или всех)?

всем привет. кто подскажет как сделать такое.
Rar a arc-name arc-file >>log%date%-%time%


>>log%date%-%time% - вот тут проблема потому как дата выводиться в виде: Mon 02/25/2008
можно ли это подправить только из командной строки ?

спасибо.

lid111
Как определить последнюю точку востановления не знаю и вообще сомневаюсь, что это будет корректным удалением точек восстановления

Код:
@echo off
setlocal

set "ds=Documents and Settings"
set "tf=Local Settings\Temp"
set "ti=Local Settings\Temporary Internet Files"

echo Start....

for %%i in (Q W E R T Y U I P O A S D F G H J K L Z X C V B N M) do (
if not %~d0==%%i: call:clean %%i
)

echo ....Done
goto:eof

:clean

if exist %1:\Windows\Temp (
    pushd %1:\Windows\Temp
    call:delete
    popd
)

if exist %1:\WinNT\Temp (
    pushd %1:\WinNT\Temp
    call:delete
    popd
)

::
:: Корзина. Встречал и Recycler и Recycled
::
if exist %1:\Recycler (
    pushd %1:\Recycler
    call:delete
    popd
)

if exist %1:\Recycled (
    pushd %1:\Recycled
    call:delete
    popd
)

:: Точки восстановления
:: Удаляет все подпапки вида RP001. У меня рабоает,
:: но я конечно не проверял на удаление
if exist "%1:\System Volume Information\*_restore*" (
    pushd "%1:\System Volume Information\*_restore*"
    for /f %%i in ('dir /b /ad') do rd /s /q %%i
    popd
)

if not exist "%1:\%ds%" goto:eof
for /f "tokens=*" %%i in ('dir /b /ad "%1:\%ds%"') do (
     if exist "%1:\%ds%\%%i\%tf%" (    
        pushd "%1:\%ds%\%%i\%tf%"
        call:delete
        popd
    )
     if exist "%1:\%ds%\%%i\%ti%" (    
        pushd "%1:\%ds%\%%i\%ti%"
        call:delete
        popd
    )
)
goto:eof

:delete
del /q /a /f *.* 1>nul 2>&1
for /f "tokens=*" %%i in ('dir /b /ad') do rd /s /q "%%i" 1>nul 2>&1

это XP - мне нужно что бы имя файла было data-time

Цитата:

%date:~-10,2%.%date:~-7,2%.%date:~-4%

спасибо , помогло.

Добавлено:
а как со временем быть ?
чёто не совсем пойму.

slech
если вывод %time% с миллисекундами

Код:
:: отсекаем последние три символа
set t=%time:~0,-3%
:: заменяем двоеточие на дефис
set t=%t::=-%
echo %t%

01MDM, всё как будто OK

Мне кстати slech своим вопросом напомнил...
В общем я нашел таки способ, как определять двумя строчками кода день-месяц-год-день недели на любой 2000\XP\2003 с любыми региональными настройками, на любой языковой версии ОС, сколько их там выпускается? XP-дистрибьютивов кажется больше сорока языков существует.

Способ простой. В папке system32 всегда есть makecab.exe. Всегда английская, других версий просто нет. У нее есть параметр [-f file.ext] - брать параметры архивирования из file.ext. Попробуйте натравить makecab на любой пустой файл, например:

Код:
makecab -f C:\MSDOS.SYS

igor_andreev
В шапку! Сейчас же!!!
P.S. В обе шапки! В "Задачи на bat-файлах" тоже.

Elroir

Цитата:

В шапку!

Согласен. Очень много "копий сломано" на форматах даты, и на нашем форуме, и в инете вообще...


Добавлено:
Вернее "копей"

Здравствуйте,

у меня такой вопрос, можно ли при помощи бат-файла
скопировать изображение на икране в bmp,jpg-файл.

Вопрос -можно ли из командной строки поменять настройки сетевого подключения (IP, шлюз, DNS, Wins) ?

sdaww
NetSh /?

KapralBel, спасибо за подсказку!

Вопрос конечно тупой, но я все равно не могу понять как сделать, делаю батник все отлично работает, но по окончанию всех операций остается висеть окно досовское, раньше я создавал ярлык pif и там можно было после завершения операций закрыть окно, но поставил новую XP и в упор такого нет, кто знает в чем траблы.

Troll
Пример батника покажи.

можно ли запускать батник в фоновом режиме, что бы его небыло видно, или хотя бы свёрнутым, что бы не вылазил на передний план ?

возможно немного не в тему.

можно ли с помощью reg.exe бэкап реестра сделать ?
всех веток в один файл.

спасибо.

Tnav

Цитата:

можно ли запускать батник в фоновом режиме

Можно с помощью сторонних утилит:
cmdow или hstart.


Цитата:

или хотя бы свёрнутым

Код: start /MIN batnik.bat

Друзья, а можно ли как-то в winXP из командной строки узнать какой нынче день недели? В Win2000 команда date показывала день недели,а в Win XP нет, как быть?

P.S. не знаю в эту тему или нет, но есть еще такая проблема... Компьютер ночью должен копировать часть файлов на сетевой диск. Батник хорошо работает днем, когда я его запускаю вручную, но сетевые диски не доступны, когда батник запускается через планировщик заданий. Как исправить ситуацию?