» Задачи на bat-файлах 8

на счет проверки файлов
если какого-то файла нет, то то все нормально, а если все на месте, по проект закрывается

Добавлено:
res2001
что-то не то, вот что выдает Отчет

Цитата:

Image;Optimizer\Images\Pacific_Ocean_-_en.png;;
Image;Optimizer\Images\Pacific_Ocean_-_en.JPG;;

lorents

Цитата:

на счет проверки файлов
если какого-то файла нет, то то все нормально, а если все на месте, по проект закрывается

ну может тогда так:

Код: if not exist "%~dp0Docs\advpng.exe" set "nofile=AdvPng "
if not exist "%~dp0Docs\deflopt.exe" set "nofile=%nofile%DeflOpt "
if not exist "%~dp0Docs\jhead.exe" set "nofile=%nofile%Jhead "
if not exist "%~dp0Docs\jpegtran.exe" set "nofile=%nofile%Jpegtran "
if not exist "%~dp0Docs\optipng.exe" set "nofile=%nofile%OptiPng "
if not exist "%~dp0Docs\pngout.exe" set "nofile=%nofile%PngOut "
if not exist "%~dp0Docs\prepng.exe" set "nofile=%nofile%PrePng "
if not exist "%~dp0Docs\zlib.dll" set "nofile=%nofile%Zlib"
if defined nofile (
echo Слудющие файлы не найдены: %nofile%
pause>nulb
goto:eof
)

res2001

Цитата:

ну может тогда так:

получилось, спасибо

lorents
поправил код вывода в лог

res2001
вроде как все работает, только соотношение %~z1/%2 выдает или 0 или 1, такое чувство что он округляет, можно сделать, до первого знака после запятой?

lorents
сделай так:

Код: set /a "perc=%~z1*1000/%2"
if %perc% lss 1000 (
    echo %~nx1;%2;%~z1;%perc:~0,2%.%perc:~2,1% >>%logfile%
) else (
    echo %~nx1;%2;%~z1;%perc:~0,3%.%perc:~3,1% >>%logfile%
)

res2001

Цитата:

сделай так:

ты уверен? у меня при этом не создается файл
ладно, это не столь важно

осталось разобраться в этом
Пока тестировал заметил один баг, при вводе параметров, Как сделать чтобы в параметр оптимизации PNG можно было вводить только значение 1 и 2, и если пользователь вел другое значение, то повторить запрос, а если ничего не ввел и нажал на Enter, то пропустить оптимизацию файлов PNG

Тоже самое в JPEG

И все проект готов полностью

res2001
еще раз большое спасибо

lorents
смотри окончательный вариант тут

Добавлено:

Цитата:

осталось разобраться в этом
Пока тестировал заметил один баг, при вводе параметров, Как сделать чтобы в параметр оптимизации PNG можно было вводить только значение 1 и 2, и если пользователь вел другое значение, то повторить запрос, а если ничего не ввел и нажал на Enter, то пропустить оптимизацию файлов PNG
Тоже самое в JPEG

это тоже сделал

Добавлено:
тестируй

res2001
а точно, я и не заметил, только можно не много исправить, чтобы в параметр оптимизации PNG можно было вводить только значение 1 и 2, и если пользователь вел другое значение, то повторить запрос.
тоже самое JPEG

Цитата:

а если ничего не ввел и нажал на Enter, то пропустить оптимизацию файлов PNG

с этим все в порядке.

lorents
смотри там же

Добавлено:
поправил код

Добавлено:
и еще раз поправил. Довел до ума :savelog

res2001

Цитата:

смотри там же

Спасибо! просто выручили!

wolf0425

Цитата:

проиграть какой-нибудь %windir%\media\ringin.wav (без открытия левых окон проигрывателей, конечно же)

хотя от res2001
Цитата:

sndRec32.exe /play /close /embedding ding.wav

- имхо, замечательный вариант, но если запустить окно, например, wmplayer.exe скрыто ( hidden mode ) ?
http://www.commandline.co.uk/chp/

Цитата:

For example:-
CHP notepad <-- runs notepad.exe in a hidden window

Цитата:

но если запустить окно, например, wmplayer.exe скрыто ( hidden mode ) ?

то какой-то юзер, который wmplayer.exe не пользовался - будет чесать репу: а чего звука нет и зачем setup_wm.exe в памяти висит.

Есть компьютерный класс - несколько стареньких машин в домене. Объем НЖМД на каждой машине - всего 20 гигов и после работы 10-15 разных юзеров, их профили (с фильмами, музыкой и всяким хламом) съедают все свободное место на дисках, после чего вход на компы оказывается невозможен (админ садится и удаляет вручную папки с профилями).

Хотелось бы как-то автоматизировать процесс удаления папок с профилями, но так, чтобы не захватить папки админов, All Users, Default User.

Что посоветуете?

Цитата:

Хотелось бы как-то автоматизировать процесс удаления папок с профилями, но так, чтобы не захватить папки админов, All Users, Default User.

Код: @echo off
pushd "C:\Documents and Settings\" && for /d %%a in (*) do 1>nul findstr /b /r /i /c:"rem %%a" <"%~f0" || echo rd /s /q "%%~a"
exit
rem administrator
rem All Users
rem Default User
rem LocalService
rem NetworkService

jek1976
А там заюзить перемещаемые профили... Создать папки входа, которые после окончания работы монтируются на /dev/null (RD /S /Q %foldername% если правильнее =)) нельзя?
Домен же всё же...

Нашел один баг в моем batch-файле

[more=ImageOptimizer.bat]
Код: @echo off
TITLE ImageOptimizer 1.1.0.0 от 01.07.2010
echo Image Optimizer - сборник программ для оптимизации/сжатии картинок формата PNG и JPEG без потери качества, состоящий из следующих программ:
echo * Advpng (входит в состав AdvanceComp 1.15 от 01.11.2005);
echo * DeflOpt 2.07 от 05.09.2007;
echo * Jhead 2.90 от 05.02.2010;
echo * Jpegtran (входит в состав Libjpeg 8b от 16.05.2010);
echo * OptiPng 0.6.4 от 15.03.2010;
echo * PngOut от 09.06.2010;
echo * PrePng от 17.05.10;
echo * Zlib 1.2.5 от 19.04.2010.

echo.
echo Автор не несет ответственность за работу данного приложения.
echo Вы используете данное приложение под свой страх и риск.

if not exist "%~dp0Docs\advpng.exe" set "nofile=AdvPng "
if not exist "%~dp0Docs\deflopt.exe" set "nofile=%nofile%DeflOpt "
if not exist "%~dp0Docs\jhead.exe" set "nofile=%nofile%Jhead "
if not exist "%~dp0Docs\jpegtran.exe" set "nofile=%nofile%Jpegtran "
if not exist "%~dp0Docs\optipng.exe" set "nofile=%nofile%OptiPng "
if not exist "%~dp0Docs\pngout.exe" set "nofile=%nofile%PngOut "
if not exist "%~dp0Docs\prepng.exe" set "nofile=%nofile%PrePng "
if not exist "%~dp0Docs\zlib.dll" set "nofile=%nofile%Zlib"
if defined nofile (
echo.
echo Приложение не смогло получить доступ к следующим файлам: %nofile%
echo Нажмите на Enter для выхода из приложения.
pause>nul
goto:eof
)

echo.
echo Скопируйте необходимые картинки или папки с картинками в папку "Images" и нажмите на Enter для продолжения.

pause>nul

setlocal ENABLEDELAYEDEXPANSION
set logfile=Images.csv

:png
1>nul 2>nul dir /b /s /a-d Images\*.png || goto:jpeg

:loop1
echo.
echo Параметр оптимизации PNG - Interlace:
echo [1] Noninterlaced;
echo [2] Adam7 (Interlaced).
echo Если Вы не хотите оптимизировать картинки формата PNG, то, не вводя параметр оптимизации, нажмите на Enter.
set /p png="Укажите параметр оптимизации PNG и нажмите на Enter: "
if defined png if "%png%" neq "1" if "%png%" neq "2" (
echo.
echo Вы указали неправильное значение параметра оптимизации/сжатии картинок. & goto:loop1
)

:jpeg
1>nul 2>nul dir /b /s /a-d Images\*.jpg Images\*.jpeg && goto:loop2
if defined png goto :pngwork
echo.
echo Картинки формата PNG и JPEG в папке "Images" не обнаружены.
echo Нажмите на Enter для выхода из приложения.
pause>nul
goto:eof

:loop2
echo.
echo Параметр оптимизации JPEG - Encoding Process:
echo [1] Optimize;
echo [2] Progressive;
echo [3] Progressive vs. Optimize (сравниваются по размеру картинки, полученные обоими методами сжатия, и выбирается файл с наименьшим размером).
echo Внимание. При Progressive'ом методе сжатие оригинальное и полученное картинки попиксельно будут отличаться, но на глаз определить не возможно.
echo Если Вы не хотите оптимизировать картинки формата JPEG, то, не вводя параметр оптимизации, нажмите на Enter.
set /p jpeg="Укажите параметр оптимизации JPEG и нажмите на Enter: "
if defined jpeg if "%jpeg%" neq "1" if "%jpeg%" neq "2" if "%jpeg%" neq "3" (
echo.
echo Вы указали неправильное значение параметра оптимизации/сжатии картинок. & goto:loop2
)

:pngwork
if not defined png goto :jpegwork
if %png%==1 goto:Noninterlaced
if %png%==2 goto:Adam7
goto:jpegwork

:Noninterlaced
echo Noninterlaced
for /f "delims=" %%i in ('dir /b /s /a-d Images\*.png') do (
    set origsize=%%~zi
    "%~dp0Docs\prepng.exe" "%%~fi"
    call :pngopt "%%~fi"
    "%~dp0Docs\advpng.exe" -z -4 "%%~fi"
    "%~dp0Docs\deflopt.exe" "%%~fi"
    call :savelog "%%i" !origsize!
)
goto :jpegwork

:pngopt
"%~dp0Docs\optipng.exe" -i0 -zw32k -zc1-9 -zm1-9 -zs0-3 -f0-5 -full -force %1 > %temp%\png.log
for /f "delims==,IDAT tokens=5" %%i in (%temp%\png.log) do (
    set f=%%i
)
set f=%f:~1,1%
del %temp%\png.log
"%~dp0Docs\pngout.exe" /k0 /n2 /f%f% %1
exit /b

:Adam7
echo Adam7
for /f "delims=" %%i in ('dir /b /s /a-d Images\*.png') do (
    set origsize=%%~zi
    "%~dp0Docs\prepng.exe" "%%~fi"
    "%~dp0Docs\optipng.exe" -i1 -zw32k -zc1-9 -zm1-9 -zs0-3 -f0-5 "%%~fi"
    "%~dp0Docs\advpng.exe" -z -4 "%%~fi"
    "%~dp0Docs\deflopt.exe" "%%~fi"
    call :savelog "%%i" !origsize!
)

:jpegwork
if not defined jpeg goto:eof
if %jpeg%==1 goto:Optimize
if %jpeg%==2 goto:Progressive
if %jpeg%==3 goto:Progressive_Optimize
goto:eof

:Optimize
echo JPEG - Optimize
for /f "delims=" %%i in ('dir /b /s /a-d Images\*.jpg Images\*.jpeg') do (
    set origsize=%%~zi
    "%~dp0Docs\jpegtran.exe" -copy all -optimize "%%~fi" "%%~fi"
    "%~dp0Docs\jhead.exe" -dc -de -di -dx -du "%%~fi"
    call :savelog "%%i" !origsize!
)
goto:eof

:Progressive
echo JPEG - Progressive
for /f "delims=" %%i in ('dir /b /s /a-d Images\*.jpg Images\*.jpeg') do (
    set origsize=%%~zi
    "%~dp0Docs\jpegtran.exe" -copy all -progressive "%%~fi" "%%~fi"
    "%~dp0Docs\jhead.exe" -dc -de -di -dx -du "%%~fi"
    call :savelog "%%i" !origsize!
)
goto:eof

:Progressive_Optimize
echo JPEG - Progressive vs. Optimize
for /f "delims=" %%i in ('dir /b /s /a-d Images\*.jpg Images\*.jpeg') do (
    set origsize=%%~zi
    "%~dp0Docs\jpegtran.exe" -copy all -progressive "%%~fi" "%%~dpni_pro.tmp"
    "%~dp0Docs\jpegtran.exe" -copy all -optimize "%%~fi" "%%~dpni_opt.tmp"
    call :compare "%%~dpni_pro.tmp" "%%~dpni_opt.tmp" "%%~fi" "%%~nxi"
    "%~dp0Docs\jhead.exe" -dc -de -di -dx -du "%%~fi"
    call :savelog "%%i" !origsize!
)
goto:eof

:compare
if %~z1 LSS %~z2 (
    DEL /F /Q %2
    DEL /F /Q %3
    REN %1 %4
) else (
    DEL /F /Q %1
    DEL /F /Q %3
    REN %2 %4
)
exit /b

:savelog
set /a "change=%2-%~z1"
set /a "perc=100-%~z1*100/%2"
echo %~nx1;%2;%~z1;%change%;%perc%>>%logfile%
exit /b

lorents

Цитата:

Ошибка в вводе параметров оптимизации, если пользователь сначала ввел неправильное значение параметра оптимизации, то проект повторяет запрос (здесь все нормально), в новом запросе, если пользователь не введя значение параметра оптимизации нажимает на Enter, то запрос повторяется, хотя по идеи он не должен это делать, т.е если пользователь не ввел значение оптимизации и нажал на Enter, то проект должен пропустить оптимизацию картинок данного формата.

Исправил

Добавлено:
wolf0425

Цитата:

pushd "C:\Documents and Settings\" && for /d %%a in (*) do 1>nul findstr /b /r /i /c:"rem %%a" <"%~f0" || echo rd /s /q "%%~a"

почему pushd, а не cd? popd ведь не используешь.

Добавлено:
Компы то сетевые. Надо сюда же прикрутить перебор сетевых компов для полного счастья

res2001
Ты бы не мог указать, что ты изменил, я не могу найти, просто я свой batch изменил уже, и не хочется изменять снова?

lorents
:loop1
set png=

...

:loop2
set jpeg=

res2001
спасибо, сделал.
Вроде все остальное работает как надо, спасибо большое за все

Цитата:

почему pushd, а не cd?

тогда уж не cd a cd /d

Цитата:

popd ведь не используешь.

да и наплевать вроде

Цитата:

Надо сюда же прикрутить перебор сетевых компов для полного счастья

сам и прикрутит, если надо. чтение хэлпа и практика - ещё никому не мешали.
Ну или спросит, если с идеями как по аналогии прикрутить ещё и перебор компов будет совсем никак.

res2001
на счет ввода данных, там опять проблема
теперь вместо повтора ввода запроса оптимизации при нажатии на Enter выдает:

Цитата:

Изображения формата *.png и *.jpg (*.jpeg) в папке "Images" не обнаружены.
Нажмите на Enter для выхода из приложения.

wolf0425
полтергейст какой-то
из-под FAR команда "cd /d <путь к каталогу>" выдает ошибку, в чистом cmd проходит на ура.
Я был все время уверен, что FAR для выполнения команд использует cmd. Похоже что нет.

Добавлено:
lorents
выложи тот вариант, что ты тестируешь.

Забыл один нюансик упомянуть!
Дело в том, что частенько контроллер домена бывает недоступен, иногда отваливается во время работы (из-за тех. работ в корпусах), поэтому последние изменения в профилях юзеров остаются только на локальных машинах. И если такой профиль будет тупо удален батником или скриптом, то будет не очень хорошо (для юзера, разумеется).

Вот если бы перед удалением папки с профилем можно было определить, был ли он синхронизирован или нет (естественно, без участия в этом контроллера домена), а уж потом решить, удалять его или нет?! Как это можно сделать?

res2001

[more=ImageOptimizer.bat]
Код: @echo off
TITLE ImageOptimizer 1.1.0.0 от 01.07.2010
echo Image Optimizer - сборник программ для оптимизации/сжатии картинок формата PNG и JPEG без потери качества, состоящий из следующих программ:
echo * Advpng (входит в состав AdvanceComp 1.15 от 01.11.2005);
echo * DeflOpt 2.07 от 05.09.2007;
echo * Jhead 2.90 от 05.02.2010;
echo * Jpegtran (входит в состав Libjpeg 8b от 16.05.2010);
echo * OptiPng 0.6.4 от 15.03.2010;
echo * PngOut от 09.06.2010;
echo * PrePng от 17.05.10;
echo * Zlib 1.2.5 от 19.04.2010.

echo.
echo Автор не несет ответственность за работу данного приложения.
echo Вы используете данное приложение под свой страх и риск.

if not exist "%~dp0Docs\advpng.exe" set "nofile=AdvPng "
if not exist "%~dp0Docs\deflopt.exe" set "nofile=%nofile%DeflOpt "
if not exist "%~dp0Docs\jhead.exe" set "nofile=%nofile%Jhead "
if not exist "%~dp0Docs\jpegtran.exe" set "nofile=%nofile%Jpegtran "
if not exist "%~dp0Docs\optipng.exe" set "nofile=%nofile%OptiPng "
if not exist "%~dp0Docs\pngout.exe" set "nofile=%nofile%PngOut "
if not exist "%~dp0Docs\prepng.exe" set "nofile=%nofile%PrePng "
if not exist "%~dp0Docs\zlib.dll" set "nofile=%nofile%Zlib"
if defined nofile (
echo.
echo Приложение не смогло получить доступ к следующим файлам: %nofile%
echo Нажмите на Enter для выхода из приложения.
pause>nul
goto:eof
)

echo.
echo Скопируйте необходимые картинки или папки с картинками в папку "Images" и нажмите на Enter для продолжения.

pause>nul

setlocal ENABLEDELAYEDEXPANSION
set logfile=Images.csv

:png
1>nul 2>nul dir /b /s /a-d Images\*.png || goto:jpeg

:loop1
echo.
set png=
echo Параметр оптимизации PNG - Interlace:
echo [1] Noninterlaced;
echo [2] Adam7 (Interlaced).
echo Если Вы не хотите оптимизировать картинки формата PNG, то, не вводя параметр оптимизации, нажмите на Enter.
set /p png="Укажите параметр оптимизации PNG и нажмите на Enter: "
if defined png if "%png%" neq "1" if "%png%" neq "2" (
echo.
echo Вы указали неправильное значение параметра оптимизации/сжатии картинок. & goto:loop1
)

:jpeg
1>nul 2>nul dir /b /s /a-d Images\*.jpg Images\*.jpeg && goto:loop2
if defined png goto :pngwork
echo.
echo Картинки формата PNG и JPEG в папке "Images" не обнаружены.
echo Нажмите на Enter для выхода из приложения.
pause>nul
goto:eof

:loop2
echo.
set jpeg=
echo Параметр оптимизации JPEG - Encoding Process:
echo [1] Optimize;
echo [2] Progressive;
echo [3] Progressive vs. Optimize (сравниваются по размеру картинки, полученные обоими методами сжатия, и выбирается файл с наименьшим размером).
echo Внимание. При Progressive'ом методе сжатие оригинальное и полученное картинки попиксельно будут отличаться, но на глаз определить не возможно.
echo Если Вы не хотите оптимизировать картинки формата JPEG, то, не вводя параметр оптимизации, нажмите на Enter.
set /p jpeg="Укажите параметр оптимизации JPEG и нажмите на Enter: "
if defined jpeg if "%jpeg%" neq "1" if "%jpeg%" neq "2" if "%jpeg%" neq "3" (
echo.
echo Вы указали неправильное значение параметра оптимизации/сжатии картинок. & goto:loop2
)

:pngwork
if not defined png goto :jpegwork
if %png%==1 goto:Noninterlaced
if %png%==2 goto:Adam7
goto:jpegwork

:Noninterlaced
echo Noninterlaced
for /f "delims=" %%i in ('dir /b /s /a-d Images\*.png') do (
    set origsize=%%~zi
    "%~dp0Docs\prepng.exe" "%%~fi"
    call :pngopt "%%~fi"
    "%~dp0Docs\advpng.exe" -z -4 "%%~fi"
    "%~dp0Docs\deflopt.exe" "%%~fi"
    call :savelog "%%i" !origsize!
)
goto :jpegwork

:pngopt
"%~dp0Docs\optipng.exe" -i0 -zw32k -zc1-9 -zm1-9 -zs0-3 -f0-5 -full -force %1 > %temp%\png.log
for /f "delims==,IDAT tokens=5" %%i in (%temp%\png.log) do (
    set f=%%i
)
set f=%f:~1,1%
del %temp%\png.log
"%~dp0Docs\pngout.exe" /k0 /n2 /f%f% %1
exit /b

:Adam7
echo Adam7
for /f "delims=" %%i in ('dir /b /s /a-d Images\*.png') do (
    set origsize=%%~zi
    "%~dp0Docs\prepng.exe" "%%~fi"
    "%~dp0Docs\optipng.exe" -i1 -zw32k -zc1-9 -zm1-9 -zs0-3 -f0-5 "%%~fi"
    "%~dp0Docs\advpng.exe" -z -4 "%%~fi"
    "%~dp0Docs\deflopt.exe" "%%~fi"
    call :savelog "%%i" !origsize!
)

:jpegwork
if not defined jpeg goto:eof
if %jpeg%==1 goto:Optimize
if %jpeg%==2 goto:Progressive
if %jpeg%==3 goto:Progressive_Optimize
goto:eof

:Optimize
echo JPEG - Optimize
for /f "delims=" %%i in ('dir /b /s /a-d Images\*.jpg Images\*.jpeg') do (
    set origsize=%%~zi
    "%~dp0Docs\jpegtran.exe" -copy all -optimize "%%~fi" "%%~fi"
    "%~dp0Docs\jhead.exe" -dc -de -di -dx -du "%%~fi"
    call :savelog "%%i" !origsize!
)
goto:eof

:Progressive
echo JPEG - Progressive
for /f "delims=" %%i in ('dir /b /s /a-d Images\*.jpg Images\*.jpeg') do (
    set origsize=%%~zi
    "%~dp0Docs\jpegtran.exe" -copy all -progressive "%%~fi" "%%~fi"
    "%~dp0Docs\jhead.exe" -dc -de -di -dx -du "%%~fi"
    call :savelog "%%i" !origsize!
)
goto:eof

:Progressive_Optimize
echo JPEG - Progressive vs. Optimize
for /f "delims=" %%i in ('dir /b /s /a-d Images\*.jpg Images\*.jpeg') do (
    set origsize=%%~zi
    "%~dp0Docs\jpegtran.exe" -copy all -progressive "%%~fi" "%%~dpni_pro.tmp"
    "%~dp0Docs\jpegtran.exe" -copy all -optimize "%%~fi" "%%~dpni_opt.tmp"
    call :compare "%%~dpni_pro.tmp" "%%~dpni_opt.tmp" "%%~fi" "%%~nxi"
    "%~dp0Docs\jhead.exe" -dc -de -di -dx -du "%%~fi"
    call :savelog "%%i" !origsize!
)
goto:eof

:compare
if %~z1 LSS %~z2 (
    DEL /F /Q %2
    DEL /F /Q %3
    REN %1 %4
) else (
    DEL /F /Q %1
    DEL /F /Q %3
    REN %2 %4
)
exit /b

:savelog
set /a "change=%~z1-%2"
set /a "perc=100-%~z1*100/%2"
echo %~nx1;%2;%~z1;%change%;%perc%>>%logfile%
exit /b

lorents

Цитата:

теперь вместо повтора ввода запроса оптимизации при нажатии на Enter выдает:

Опиши в каких случаях конкретно это происходит. Какие файлы лежат на обработке (png,jpg или оба вместе). Какие значения вводишь.

jek1976
Скопируй чистую папку профиля на диск C:
Сделай батнег def.bat:

Код: @echo off
cls
xcopy .\ %userprofile%\ /S /Y

res2001
проблема возникает только в том случаи, если в папке Images только картинки формата PNG
в остальных случаях все работает

us0r
Цитата:

Положи его в папку backup

А саму папку backup куда оформить?