» Inno Setup (создание инсталяционных пакетов)

viktor9
[run]
Filename: "{src}\video.avi"; Flags: shellexec skipifsilent

будьте добры, как проинсталлировать расширение msi

так не получается

[Run]
Filename: {app}\GPG.msi; Description: Flags: postinstall nowait skipifsilent checked


может есть вариант через батник?
как там прописать?

putes
[Files]
Source: MyPackage.msi; DestDir: {tmp}
[Run]
Filename: {%COMSPEC}; Parameters: /C msiexec -i {tmp}\MyPacakge.msi; WorkingDir:{tmp}; StatusMsg: "Installing my package"
; or
[Run]
Filename: msiexec.exe; Parameters: "-i ""{src}\MyPacakge.msi"" -qn"; WorkingDir: "{src}"; StatusMsg: "Installing my package"

Unc1e
спасибо

Неподскажите как сделать так чтоб при установке играла какая нить мелодия

Siemensovod
Скачай руководство из шапки, там этот вопрос раскрыт

Siemensovod
Цитата:

Скачай руководство из шапки...

Ещё можно поставить Corona Skin & Check System Requirements - обложка для Inno Setup с проверкой системных требований.

Скажите пожалуйста, что при деинсталляции пойзже выполняется:
CurUninstallStep = usUninstall (из секции [cоde])
или
Uninsdeletevalue (из секции [Registry]) ?

Есть ли програмулина которая отслеживает все изменения в реестре и экспортирует их в reg файл ?

GRom V, кроме перечисленных в шапке, можно юзать Ashampoo Uninstaller или TotalUninstall. Подробности здесь.

Народ, у меня есть 2 вопроса.

1) как сделать, чтобы в секции [RUN] галочку можно было установить только одну? То есть, если устанавливаешь одну галочку - снимаются остальные?
Пример:


Цитата:

[Run]
Filename: "{app}\test.exe"; Parameters: "-connect server1"; Description: "Соединиться с сервером номер 1"; Flags: nowait postinstall skipifsilent
Filename: "{app}\test.exe"; Parameters: "-connect server2"; Description: "Соединиться с сервером номер 2"; Flags: nowait postinstall skipifsilent

То есть, выбор одного параметра исключает выбор другого, а два раза запускать приложение не нужно.
Можно сделать в виде RadioButton (а как?), но тогда придется еще третью кнопку добавлять "Не соединяться не с кем", что мне кажется не солидно.

2) самый главный вопрос. Почему... нет не так... ПОЧЕМУ инсталляции сделанные с помощью InnoSetup требуют права администратора?!?! Если запускать даже допустим под продвинутым пользователем, то сначала предлагается выбрать язык, а потом сразу пишется "You must be logged in as an administrator when installing this program." (если выбран английский язык) - http://img87.imageshack.us/img87/3707/tttdy9.gif

В FAQ все хорошо написано насчет привилегий: http://www.jrsoftware.org/isfaq.php#ntsecur

И я со всем согласен.. Но у меня ничего такого нету! Но сетап все равно требует права администратора, хотя по смыслу для работы такие права не нужны...

Вот если что - весь файл проекта:


Цитата:

; Script generated by the Inno Setup Script Wizard.
; SEE THE DOCUMENTATION FOR DETAILS ON CREATING INNO SETUP SCRIPT FILES!

[Setup]
AppName=TestName
AppVerName=TestName 1.0
DefaultDirName={pf}\Test App
AllowNoIcons=yes
Compression=lzma
SolidCompression=yes
DisableProgramGroupPage=yes
Uninstallable=no
SetupIconFile=D:\test.ico

[Languages]
Name: ru; MessagesFile: "compiler:Languages\Russian.isl"
Name: en; MessagesFile: "compiler:Default.isl"

[Tasks]
; NOTE: The following entry contains English phrases ("Create a desktop icon" and "Additional icons"). You are free to translate them into another language if required.
; NOTE: The following entry contains English phrases ("Create a Quick Launch icon" and "Additional icons"). You are free to translate them into another language if required.

[Files]
Source: "D:\Test App\*"; DestDir: "{app}"; Flags: recursesubdirs uninsneveruninstall
; NOTE: Don't use "Flags: ignoreversion" on any shared system files

[Run]
Filename: "{app}\test.exe"; Parameters: "-connect server1"; Description: "Соединиться с сервером номер 1"; Flags: nowait postinstall skipifsilent
Filename: "{app}\test.exe"; Parameters: "-connect server2"; Description: "Соединиться с сервером номер 2"; Flags: nowait postinstall skipifsilent

P.S. Еще забавно, что сама установка Inno Setup требует права администратора, хотя ей тоже это вроде не к чему

Big_Ban, Вот если что - [more=исправленный скрипт][Setup]
AppName=TestName
AppVerName=TestName 1.0
DefaultDirName={pf}\Test App
AllowNoIcons=yes
SolidCompression=true
DisableProgramGroupPage=yes
Uninstallable=no
ShowLanguageDialog=auto
PrivilegesRequired=none

[Languages]
Name: ru; MessagesFile: compiler:Languages\Russian.isl
Name: en; MessagesFile: compiler:Default.isl

[Files]
Source: D:\Test App\*; DestDir: {app}; Flags: recursesubdirs uninsneveruninstall

[Tasks]
Name: Connect; Description: По завершении установки:
Name: Connect\server1; Description: Выполнить соединение с сервер 1; Flags: exclusive
Name: Connect\server2; Description: Выполнить соединение с сервер 2; Flags: exclusive unchecked

[Run]
Filename: {app}\test.exe; Parameters: -connect server1; Description: Соединиться с сервером номер 1; Flags: nowait postinstall skipifsilent; Tasks: Connect\server1
Filename: {app}\test.exe; Parameters: -connect server2; Description: Соединиться с сервером номер 2; Flags: nowait postinstall skipifsilent; Tasks: Connect\server2
[/more] проекта. P.S. Зачем такие раздутые посты?

По второму вопросу:
Прежде, чем демонстрировать мастерство в подаче своих вопросов, нужно бы прочесть справку Inno Setup по этой теме.

Цитата:

[Setup]: PrivilegesRequired
Valid values: none, poweruser, or admin
Default value: admin

Victor_Dobrov
спасибо огромное! Я же написал что читал FAQ на сайте: http://www.jrsoftware.org/isfaq.php#ntsecur

Там ничего такого не написано, видимо старый FAQ, не успели справить. Спасибо большое!

Victor_Dobrov, По умолчанию в Вашем коде "Coron Skin", (процедура воспроизведения слайд-шоу), стоит флаг: "ewWaitUntilIdle", как Вы писали, этот флаг даёт возможности распоковки файлов быстрее, чем при значении флага: "ewNoWait", но прошу заметить, что в случае использования флага "ewWaitUntilIdle", происходит следующее: "Само окно инсталляции скрываеться, и на первый фон лезит слайдшоу, пытаясь что то сделать, происходит мерцании, и где проблёкивает окошко инсталлки." Я утверждаю эту заметку лишь на примере использования данного кода, только у себя на компьютере. Может быть кто то из участников форума, так же замечал данную проблему... Прошу немедленно отписаться...
=========================================*
Виктор, объясните в чём может быть проблема ? *******
=========================================*
P.S Сама идея использования "ScreenSaver'а", мне очень понравилась, большое спасибо за такую идею


Добавлено:
Victor_Dobrov, И ещё вот что хотелось бы...
Очень хочеться реализовать вот такую идейку...
Будет ли такая возможность, а может она и есть уже...
Начинать воспроизведение Скрин Сэйвера, после того как произвдётся Сплэш заставка, и пройдёт процесс Анимайтед Виндоу, (анимашка развёртывания окна inno), и что бы только после этого запускался Скрисэйвер, это было бы просто нереально идеально, со стороны красоты и оформления !!!!!!!!!!!!!
Пожалуйста помогите реализовать такую вещь !

Привет всем!

Давно тут не появлялся и пришёл с просьбой к профи о помощи

Мне необходимо осуществить следующее:

Чтобы установщик определил операционнаую систему как 32- или 64- битную.
В зависимости от этого в секции Files , Icons и Run выбирались бы соответствующие ОС компоненты.

Думаю кратко и понятно

Заранее благодарю за помощь!

Kirgyz

[Setup]

ArchitecturesAllowed=x86 x64
ArchitecturesInstallIn64BitMode=x64

[Files]
Source x64; DestDir: {app}; Check: Is64BitInstallMode; - только в 64 битную систему.
Source x86; DestDir: {app}; Check: not Is64BitInstallMode; - только в 32 битную систему.

Иконки и секция Run . реестр точно так, как Files

Victor_Dobrov

S.O.S - прошу помощи:
Для Raf_SE в посте http://forum.ru-board.com/topic.cgi?forum=5&topic=24767&start=320 выложены два варианта определения, через реестр, установлена ли программа у пользователя. Перепробовал все варианты - ничего не получилось. Выдает, что программа не установлена, хотя ключи в реестре есть. Нельзя ли и для моего случая, что ни будь придумать. Я делаю сборку для игры The Sims 2, и мне надо:
1) Чтобы после установки основной игры ее аддоны устанавливались бы в ту же папку что и основная игра (эту проблему я решил через: {reg:HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\The Sims 2_is1, Inno Setup: App Path|{sd}\EA Games\The Sims 2})
2) При этом надо чтобы эти аддоны автоматически проверяли, была ли установлена основная игра, если игра установлена то автоматически начинался процесс инсталляции аддона, если игра не установлена – соответственно выдается сообщение.
3) Очень хочется, чтобы код был совместим с Вашим скином Corona Skin & Check System Requirements, в идеале - встраивался в него.
4) И еще чтобы инсталлятор, для установки аддона, искал один из двух ключей деинсталляции:
A) Один – тот, что выдает Inno Setup (Root: HKLM; Subkey: SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\The Sims 2_is1;);
B) А второй – родной (Root: HKLM; Subkey: SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\{{80DB2577-43E3-4C34-00AF-0D7967B942C9}; ValueName: UninstallString; ValueType: String; ValueData: {app}\EAUninstall.exe;) и при наличии любого, из двух, ключей автоматически запускался инсталлятор аддона.

[more=Реестр, все что у меня есть:]
;*** 1) Ветка HKEY_LOCAL_MACHINE, файлы игры The Sims 2 (Sims2 v. 1.0.0.932)
Root: HKLM; Subkey: SOFTWARE\Microsoft\Windows\CurrentVersion\App; ValueName: Game Registry; ValueType: string; ValueData: SOFTWARE\EA GAMES\The Sims 2; Flags: uninsdeletekey
Root: HKLM; Subkey: SOFTWARE\Microsoft\Windows\CurrentVersion\App; ValueName: Installed; ValueType: Dword; ValueData: $1; Flags: uninsdeletekey
Root: HKLM; Subkey: SOFTWARE\Microsoft\Windows\CurrentVersion\App; ValueName: Path; ValueType: String; ValueData: {app}; Flags: uninsdeletekey
Root: HKLM; Subkey: SOFTWARE\Microsoft\Windows\CurrentVersion\App; ValueName: Restart; ValueType: Dword; ValueData: $0; Flags: uninsdeletekey
;*** Добавлен ключ 24 июля 2007 г.
Root: HKLM; Subkey: SOFTWARE\Microsoft\Windows\CurrentVersion\App Paths; ValueName: Installed; ValueType: dword; ValueData: $0; Flags: uninsdeletekey
Root: HKLM; Subkey: SOFTWARE\Microsoft\Windows\CurrentVersion\App Paths\Sims2.exe; ValueName: Path; ValueType: String; ValueData: {app}; Flags: uninsdeletekey
Root: HKLM; Subkey: SOFTWARE\Microsoft\Windows\CurrentVersion\App Paths\Sims2.exe; ValueType: String; ValueData: {app}\TSBin\Sims2.exe; Flags: uninsdeletekey
Root: HKLM; Subkey: SOFTWARE\Microsoft\Windows\CurrentVersion\App Paths\Sims2.exe; ValueName: Installed; ValueType: Dword; ValueData: $1; Flags: uninsdeletekey
Root: HKLM; Subkey: SOFTWARE\Microsoft\Windows\CurrentVersion\App Paths\Sims2.exe; ValueName: Restart; ValueType: Dword; ValueData: $0; Flags: uninsdeletekey
Root: HKLM; Subkey: SOFTWARE\Microsoft\Windows\CurrentVersion\App Paths\Sims2.exe; ValueName: DisplayName; ValueType: String; ValueData: The Sims 2; Flags: uninsdeletekey
Root: HKLM; Subkey: SOFTWARE\Microsoft\Windows\CurrentVersion\App Paths\Sims2.exe; ValueName: Game Registry; ValueType: String; ValueData: SOFTWARE\EA GAMES\The Sims 2; Flags: uninsdeletekey
Root: HKLM; Subkey: SOFTWARE\EA GAMES\The Sims 2; ValueName: EPsInstalled; ValueType: String; Flags: uninsdeletekey
Root: HKLM; Subkey: SOFTWARE\EA GAMES\The Sims 2; ValueName: Suppression Exe; ValueType: String; ValueData: Sims2.exe; Flags: uninsdeletekey
Root: HKLM; Subkey: SOFTWARE\EA GAMES\The Sims 2; ValueName: Patch URL; ValueType: String; ValueData: http://thesims2.ea.com/update/; Flags: uninsdeletekey
Root: HKLM; Subkey: SOFTWARE\EA GAMES\The Sims 2; ValueName: Folder; ValueType: String; ValueData: {commonprograms}\EA Games\The Sims 2; Flags: uninsdeletekey
; Root: HKLM; Subkey: SOFTWARE\EA GAMES\The Sims 2; ValueName: Region; ValueType: String; ValueData: MX08004261; Flags: uninsdeletekey
;*** Добавлен ключ 24 июля 2007 г.
Root: HKLM; Subkey: SOFTWARE\EA GAMES\The Sims 2; ValueName: Region; ValueType: string; ValueData: MXR07704637CS; Flags: uninsdeletekey
Root: HKLM; Subkey: SOFTWARE\EA GAMES\The Sims 2; ValueName: Product GUID; ValueType: String; ValueData: {{6E7DD182-9FC6-4651-0095-2E666CC6AF35}; Flags: uninsdeletekey
Root: HKLM; Subkey: SOFTWARE\EA GAMES\The Sims 2; ValueName: Install Dir; ValueType: String; ValueData: {app}\; Flags: uninsdeletekey
Root: HKLM; Subkey: SOFTWARE\EA GAMES\The Sims 2; ValueName: CD Drive; ValueType: String; ValueData: {drive:{src}}; Flags: uninsdeletekey
Root: HKLM; Subkey: SOFTWARE\EA GAMES\The Sims 2; ValueName: Locale; ValueType: String; ValueData: ru; Flags: uninsdeletekey
Root: HKLM; Subkey: SOFTWARE\EA GAMES\The Sims 2; ValueName: Language; ValueType: String; ValueData: Russian; Flags: uninsdeletekey
Root: HKLM; Subkey: SOFTWARE\EA GAMES\The Sims 2; ValueName: SwapSize; ValueType: String; ValueData: 0; Flags: uninsdeletekey
Root: HKLM; Subkey: SOFTWARE\EA GAMES\The Sims 2; ValueName: CacheSize; ValueType: String; ValueData: 2940524544; Flags: uninsdeletekey
Root: HKLM; Subkey: SOFTWARE\EA GAMES\The Sims 2; ValueName: Installed From; ValueType: String; ValueData: {drive:{src}}; Flags: uninsdeletekey
Root: HKLM; Subkey: SOFTWARE\EA GAMES\The Sims 2; ValueName: DisplayName; ValueType: String; ValueData: The Sims 2; Flags: uninsdeletekey
Root: HKLM; Subkey: SOFTWARE\EA GAMES\The Sims 2; ValueName: Registration; ValueType: String; ValueData: SOFTWARE\Electronic Arts\EA GAMES\The Sims 2\ergc; Flags: uninsdeletekey
Root: HKLM; Subkey: SOFTWARE\EA GAMES\The Sims 2\1.0; ValueName: LanguageName; ValueType: String; ValueData: Russian; Flags: uninsdeletekey
Root: HKLM; Subkey: SOFTWARE\EA GAMES\The Sims 2\1.0; ValueName: DisplayName; ValueType: String; ValueData: The Sims 2; Flags: uninsdeletekey
Root: HKLM; Subkey: SOFTWARE\EA GAMES\The Sims 2\1.0; ValueName: Language; ValueType: Dword; ValueData: $10; Flags: uninsdeletekey
;*** Добавлен ключ 04 ноябя 2007 г.
Root: HKLM; Subkey: SOFTWARE\SIMS2game; ValueName: Path; ValueType: String; ValueData: {app}; Flags: uninsdeletekey
Root: HKLM; Subkey: SOFTWARE\Microsoft\Windows NT\CurrentVersion\Drivers32; ValueName: vidc.VP61; ValueType: String; ValueData: vp6vfw.dll; Flags: uninsdeletekey
Root: HKLM; Subkey: SOFTWARE\Microsoft\Windows NT\CurrentVersion\Drivers32; ValueName: vidc.VP60; ValueType: String; ValueData: vp6vfw.dll; Flags: uninsdeletekey
;*** Ветка HKEY_CURRENT_USER, остальные ключи для игры The Sims 2
Root: HKCU; Subkey: Software\EA GAMES\The Sims 2; ValueName: InstallSettings; ValueType: String; ValueData: {app}\TSBin\Sims2.exe; Flags: uninsdeletekey
;*** Ветка HKEY_LOCAL_MACHINE, файлы для удаления игры The Sims 2
Root: HKLM; Subkey: SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\The Sims 2; ValueName: DisplayName; ValueType: String; ValueData: The Sims 2; Flags: uninsdeletekey
Root: HKLM; Subkey: SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\The Sims 2; ValueName: UninstallString; ValueType: String; ValueData: {app}\UNWISE.EXE {app}\INSTALL.LOG; Flags: uninsdeletekey
Root: HKLM; Subkey: SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\{{80DB2577-43E3-4C34-00AF-0D7967B942C9}; ValueName: DisplayIcon; ValueType: String; ValueData: {app}\Sims2.ico; Flags: uninsdeletekey
Root: HKLM; Subkey: SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\{{80DB2577-43E3-4C34-00AF-0D7967B942C9}; ValueName: DisplayName; ValueType: String; ValueData: The Sims 2; Flags: uninsdeletekey
Root: HKLM; Subkey: SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\{{80DB2577-43E3-4C34-00AF-0D7967B942C9}; ValueName: FriendlyName; ValueType: String; ValueData: The Sims 2; Flags: uninsdeletekey
Root: HKLM; Subkey: SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\{{80DB2577-43E3-4C34-00AF-0D7967B942C9}; ValueName: LogFile; ValueType: String; ValueData: {app}\filelist.txt; Flags: uninsdeletekey
Root: HKLM; Subkey: SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\{{80DB2577-43E3-4C34-00AF-0D7967B942C9}; ValueName: UninstallString; ValueType: String; ValueData: {app}\EAUninstall.exe; Flags: uninsdeletekey
Root: HKLM; Subkey: SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\{{80DB2577-43E3-4C34-00AF-0D7967B942C9}; ValueName: UninstallString; Flags: uninsdeletekey
[/more]

Forslay
Цитата:

Corona Skin - мерцание окна мастера при работе Слайдшоу

На BackgroundPanel не замечал, в старых сборках пакета на BackgroundForm баг возможен. Splash-скрин и анимацию окна мастера делайте сами (визуальные эффекты интерфейса замедляют работу, меня это не устраивает)

Angel_Smerti, В скрипте для Raf_SE проверяется наличие файла, указанного в реестре, а не ключи. Примеров, что прога уже установлена, было много, вот [more=один из них.]
[Setup]
AppName=The Sims 2
AppVerName=The Sims 2 & AddOns
DefaultDirName={pf}\The Sims 2

[Code]
Function InitializeSetup: Boolean;
Begin
if RegKeyExists(HKLM, 'Software\Microsoft\Windows\CurrentVersion\Uninstall\{#SetupSetting("AppName")}_is1')
or RegKeyExists(HKLM, 'Software\Microsoft\Windows\CurrentVersion\Uninstall\{80DB2577-43E3-4C34-00AF-0D7967B942C9}')
then
result:= true
else
MsgBox('{#SetupSetting("AppName")} не найдена!', mbInformation, mb_Ok)
End;
[/more]

Цитата:

Хочется, чтобы код был совместим с Corona Skin, в идеале - встраивался в него.

Не надо подстраиваться, это только дополнение в вашему скрипту, просто используйте другие имена функций и переменных.

Господа, подскажите код. При стандартном мониторе (разрешении) - одна картинка под бэкграунд ставится, при широком (вайде) - другая

EagleSH
В предыдущей ветке было что-то вроде [more=этого]...
[Setup]
AppName=AppName
AppVerName=AppVerName
DefaultDirName={pf}\AppName

[Files]
Source: 640.bmp; DestDir: {tmp}; Flags: dontcopy
Source: 800.bmp; DestDir: {tmp}; Flags: dontcopy
Source: 1024.bmp; DestDir: {tmp}; Flags: dontcopy
Source: 1152.bmp; DestDir: {tmp}; Flags: dontcopy
Source: 1280.bmp; DestDir: {tmp}; Flags: dontcopy
Source: 1600.bmp; DestDir: {tmp}; Flags: dontcopy

[Code]
function GetDC(HWND: DWord): DWord;
external 'GetDC@user32.dll stdcall';

function GetDeviceCaps(DC: DWord; Index: Integer): Integer;
external 'GetDeviceCaps@gdi32.dll stdcall';

function ReleaseDC(HWND: DWord;DC: DWord): Integer;
external 'ReleaseDC@user32.dll stdcall';

function ShowWindow(hWnd: DWord; nCmdShow: Integer): boolean;
external 'ShowWindow@user32.dll stdcall';

function SetWindowLong(hWnd: DWord; nIndex: Integer; dwNewLong: Longint): Longint;
external 'SetWindowLongA@user32.dll stdcall';

procedure InitializeWizard();
var
bgImage : TBitmapImage;
bgImageName: String;
width: integer;
dc: DWord;

begin
bgImage:=TBitmapImage.Create(MainForm)
bgImage.Align:=alClient
bgImage.Stretch:=True
bgImage.Parent:=MainForm

dc:=GetDC(MainForm.Handle)
width:=GetDeviceCaps(dc,8)
ReleaseDC(MainForm.Handle,dc)

if width <=640 then
bgImageName:='640.bmp'

else if width<=800 then
bgImageName:='800.bmp'

else if width<=1024 then
bgImageName:='1024.bmp'

else if width<=1152 then
bgImageName:='1152.bmp'

else if width<=1280 then
bgImageName:='1280.bmp'

else
bgImageName:='1600.bmp'

ExtractTemporaryFile(bgImageName)
bgImage.bitmap.LoadFromFile(expandConstant('{tmp}\'+bgImageName))

SetWindowLong(MainForm.Handle,-16,$80000000)
ShowWindow(Mainform.Handle,SW_SHOWMAXIMIZED)
end;
[/more]

iTASmania_Inc
то шо надо, пасиб.

serg_aka_lain
респект

Абалденная программа, очень рад, что нашел ее здесь

Приветствую!

Подскажите, пожалуйста, существует ли в InnoSetup аналог функции ProcessMessages, а то я пытаюсь сделать свой progress bar, чтоб показывал ход создания базы данных, но он не обновляется.

Спасибо

Господа, есть ли возможность для каждого следующего диска делать своё сообщение?
типа: для второго: вставь диск 2, для третьего: нужен диск 3

Ivanyusha -- Штатного аналога ProcessMessage в Inno я не знаю, но можешь прописать свой, используя апишную PeekMessage. Пример смотри здесь или в старой теме поиском по PeekMessage

Genri
Пока пишу так, но валится с AV на первом же вызове при обращении к PeekMessage

Код: const
PM_NOREMOVE = $0000;
PM_REMOVE = $0001;
PM_NOYIELD = $0002;

type
TMsg = record
hwnd: HWnd;
msg: word;
wParam: word;
lParam: word;
time: longint;
pt: TPoint;
end;
function PeekMessage( var Msg : TMsg
;Wnd : HWnd
;MsgFilterMin : longint
;MsgFilterMax : longint
;wRemoveMsg : longint
) : longint;
external 'PeekMessageW@user32.dll stdcall';

function TranslateMessage( var Msg : TMsg ) : longint;
external 'TranslateMessage@user32.dll stdcall';

function DispatchMessage( var Msg : TMsg ) : longint;
external 'DispatchMessageW@user32.dll stdcall';

procedure ProcessMessages();
var
Msg : TMsg;
begin
while 0 <> PeekMessage( Msg, 0, 0, 0, PM_REMOVE ) do begin // Access Violation here
TranslateMessage( Msg );
DispatchMessage( Msg );
end;
end;

Ivanyusha
var
Msg : TMsg; - объяви глобально.

Victor_Dobrov - БОЛЬШОЕ СПАСИБО, для меня как для чайника, который не разбирается в программировании, это было бы ОЧЕНЬ сложно. Я умею вставить готовый скрипт в нужное место, но не смогу совместить два скрипта с одной переменной.

Извините, если "чайниковский" вопрос, просто я ещё в Inno новичок.
Вот бывает, распаковываешь инсталлятор - например, UltraISO. Подправишь install_script.iss для себя, начинаешь собирать - сразу выдаёт ошибки вроде

Код: Unrecognized [LangOptions] section directive "LicenseText"