» Командная строка, батники, сценарии (bat, cmd)

Dr29BArt
Если ХР, то на панели управления Система -> Дополнительно -> Переменные среды

01MDM
спасибо. А как это в скрипте? Так?
@echo off
bitsadmin /transfer "test" /download /priority normal http://ya.ru "%cd%\index.html"

if not exist index.html (
rasdial "vpn_name" /disconnect
rasdial "vpn_name" vpn_login vpn_password
)
2>nul del index.html

Mosl
Да, так. Но все таки wget побыстрей работает, а bitsadmin у меня пару раз вылетал на ровном месте с ошибкой.
Только слегка измени строчку:

Код:
bitsadmin /transfer "test" /download /priority normal http://ya.ru "%~dp0index.html"

hiqmax, ёлки-палки спасибо конечно, но я подразумевал ответ в виде кода исполняемого файла *.bat, в данной теме. Может всё таки есть идеи?

01MDM
не сработал скрипт:
Код: @echo off
cmd /c wget ya.ru

if not exist index.html (
rasphone.exe -h "Beeline"
rasphone.exe -d "Beeline"
)
2>nul del index.html

Mosl
Не знаю. У меня оба варианта работают. Может яндекс забанили в украине? Попробуй google.com или еще какую-нибудь "легкую" страницу.
Вот вывод wget:

Код:
> wget ya.ru
SYSTEM_WGETRC = c:/progra~1/wget/etc/wgetrc
syswgetrc = C:\Users\mdm\BIN\Gnu/etc/wgetrc
--2009-10-12 20:20:35-- http://ya.ru/
Распознаётся ya.ru... 93.158.134.8, 213.180.204.8, 77.88.21.8
Устанавливается соединение с ya.ru|93.158.134.8|:80... соединение установлено.
Запрос HTTP послан, ожидается ответ... 200 OK
Длина: 4891 (4,8K) [text/html]
Сохраняется в каталог: `index.html'.

100%[================================================>] 4 891 --.-K/s в 0s

2009-10-12 20:20:35 (105 MB/s) - `index.html' сохранён [4891/4891]

01MDM
ты не понял. Никто нечего не забанил. Я имел виду что в цикл уходит когда нет соединения (связи с ресурсом)! Скрипт продолжает опрашивать его раз за разом и не переходит к выполнению задачи соединения. Я решил добавив параметр -t 1 ("wget -t 1" - он задает количество попыток). И убрал cmd /c так как с ним после выполнения wget -t 1 ya.ru (в случае не доступности) дальше скрипт не выполнялся.
Скрипт в таком виде отробатывает коректно:

Код: @echo off
wget -t 1 ya.ru

if not exist index.html (
rasphone.exe -h "Beeline"
rasphone.exe -d "Beeline"
)
2>nul del index.html

Mosl

Подозреваю просто различия в gnuwget и winwget.

"cmd /c wget" использую по привычке. Однажды долго не мог понять почему не отрабатывает батник. Оказалось, что wget при неудачной закачке просто завершал батник. Поэтому и запускаю его в отдельной cmd.

Хотел бы написать простенький батник, для удаления кое каких папок и нескольких ключей реестра.

Собственно вот что нужно: там где я учусь стоят ноды с триалом, разорится на лицу не кто не хочет, вот и переставляем каждые 30 дней. И как то надоедает удалять папки оставшиеся после нода, а потом ещё в реестре. Хотелось бы написать батник, что бы удалял папки(желательно, что бы выводился запрос на удаление: да\нет), допустим по имени ESET и определённые ключи реестра.
С реестром то я и не знаю, что сделать, с папками тоже средне.....

Скажите а возможно ли при помощи пакетного файла определить букву съемного диска или флешки?

N1G

Цитата:

при помощи пакетного файла определить букву съемного диска или флешки?

Выбирай:

Код:
@echo off
setlocal

::1
set "exec=echo list volume ^| diskpart ^| findstr Removable"
for /f "tokens=3" %%i in ('%exec%') do echo %%i:

::2
set "exec=wmic logicaldisk where drivetype^="2" get name /value"
for /f "tokens=2 delims==" %%i in ('%exec%') do echo %%i

::3
for %%i in (q w e r t y u i o p a s d f g h j k l z x c v b n m) do (
    fsutil fsinfo drivetype %%i: | 1>nul findstr Removable && echo %%i:
)

Где читал, что можно написать простенький батник, что бы он создавал в папке с файлами тхт файлик в котором будут написаны имена файлов(с расширением) и папок.
Кто знает как это сделать?

B16
По первому вопросу, удалять заранее известные папки и ключи реестра можно простыми командами:

Код:
@echo off
rd /s /q "%ProgramFiles%\Eset"
rd /s /q "C:\Test\Test"

reg delete "HKLM\Software\Eset" /f

to 01MDM

Спасибо огромное за предложенный вариант!


Цитата:

@echo off
setlocal

set "exec=wmic logicaldisk where drivetype^="2" get name /value"
for /f "tokens=2 delims==" %%i in ('%exec%') do echo %%i

А можно ли выполнить сортировку от диска A:\, а то к примеру оны выдаёт A:\ и G:\
т.е. флопик он всегда определяет.

N1G

Цитата:

А можно ли выполнить сортировку от диска A:\, а то к примеру оны выдаёт A:\ и G:\
т.е. флопик он всегда определяет.

Т.е. Исключить A: ? Исправь строку:

Код:
set "exec=wmic logicaldisk where ^(drivetype^="2" AND name!^="A:"^) get name /value"

Благодарю!

01MDM
Хотел что спросить. Может у вас будут какие идеи. Почему один и тот же *.cmd файл может правильно отрабатываться при запуске в ручную, но при этом не правильно отрабатываться при запуске через планировщик задач?
Если помните:

Код: @echo off
wget -t 1 ya.ru
if not exist index.html (
rasphone.exe -h "Beeline"
rasphone.exe -d "Beeline"
)
2>nul del index.html

потому что (скорее всего - так я сильно пьян у меня строчки в глазах прыгают) при запуске из другой директории рабочая директория получается та откуда его запустили нуна добавить строку

CD /D %~DP0
это сменит рабочую директория на ту где валяется сам бантник

Mosl
bomzzz прав. "%~DP0" в кавычках, если в пути к батнику есть пробелы

это так что ли:

Код: @echo off
CD /D %~DP0
wget -t 1 ya.ru
if not exist index.html (
rasphone.exe -h "Beeline"
rasphone.exe -d "Beeline"
)
2>nul del index.html

Mosl

Код:
@echo off
pushd "%~dp0" или cd /d

wget -t 1 ya.ru
if not exist index.html (
rasphone.exe -h "Beeline"
rasphone.exe -d "Beeline"
)
2>nul del index.html

Помогите устал руками править.

Есть пака в ней много твиков реестра

001-Классический вид Панели управления.reg

Код: Windows Registry Editor Version 5.00

[HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Policies\Explorer]
"ForceClassicControlPanel"=dword:00000001

omamont

Код:
@echo off
for %%i in (*.reg) do sed -i "2 s/^.*$/;%%~ni/" "%%i"

:: del sed* - если создаются временные файлы вида sedQWHjNy

del sed*

добрый день, помогите начинающему.

нужно, чтобы скрипт в цикле проверял есть ли файл в папке, если есть, то чтобы он его перемещал во второй каталог, а из второго копировал в третий. ну и так постоянно.

заранее спасибо.

01MDM не сработало - пишет:

Цитата:

"sed" не является внутренней или внешней
командой, исполняемой программой или пакетным файлом.

и так много раз.
положил несколько файлов для примера которые надо редактировать
здесь: http://rghost.ru/537803/private/3d3a5f289d95ab7aca2261691fd7bf92

omamont
http://gnuwin32.sourceforge.net/packages/sed.htm

01MDM

ОГРОМНОЕ СПАСИБО помогло - работает !!!

А баз сторонних утилит - никак ?
типа: заменить в файле строчку

Код: @Echo Off
::заменить в файле строку "Temp=" на "Temp=268698540,027KJIGEIOHTEXO"
Call :SkipAdd "%ProgramFiles%\WinTools.netProfessional\wintoolspro.ini"
Exit

:SkipAdd
FindStr /IBVC:"Temp=" "%~f1">"%~dpn1.tmp"
Echo Temp=268698540,027KJIGEIOHTEXO>>"%~dpn1.tmp"
If Exist "%~dpn1.bak" DEL /F/Q "%~dpn1.bak"
Ren "%~f1" "%~n1.bak"
Ren "%~dpn1.tmp" "%~nx1"
DEL /F/Q "%~dpn1.bak"
Exit /B

omamont

Цитата:

А баз сторонних утилит - никак ?

Да нет:

Код:
@echo off
for %%i in (*.reg) do (

    1>"%%~ni.temp" (
        echo Windows Registry Editor Version 5.00
        echo ;%%~ni
        more +2 "%%i"
    )
    
    move "%%~ni.temp" "%%i"
)

Цитата:

В данном случае можно и так, просто не люблю батником работать с текстом.

кракозябры

Код: Windows Registry Editor Version 5.00
;168-ЋвЄ«озЁвм ®б- бвЄг 'Cўo©cвўa cЁcвe¬л' - эт 2й вариант
;168-Отключить оснастку 'Cвoйcтвa cиcтeмы'
[HKEY_CURRENT_USER\Software\Policies\Microsoft\MMC\{0F3621F1-23C6-11D1-AD97-00AA00B88E5A}]
"Restrict_Run"=dword:00000001

omamont

Цитата:

кракозябры

надо указать кодировку (cp1251). Сразу с подпапками:

Код:
@echo off
1>nul chcp 1251

for /f "tokens=*" %%i in ('dir /b /s /a *.reg') do (

1>"%%~ni.temp" (
echo Windows Registry Editor Version 5.00
echo ;%%~ni
more +2 "%%i"
)

move "%%~ni.temp" "%%i"
)